
package Plack::Middleware::DetectMobileBrowsers;
{
  $Plack::Middleware::DetectMobileBrowsers::VERSION = '0.03';
}

# ABSTRACT: Automatically set a flag in the environment if a mobile client is detected

use strict;
use warnings;

use parent qw(Plack::Middleware);
use Plack::Util::Accessor qw( env_key tablets_as_mobile );

my $re_a_noTablets   = qr/(android|bb\d+|meego).+mobile|avantgo|bada\/|blackberry|blazer|compal|elaine|fennec|hiptop|iemobile|ip(hone|od)|iris|kindle|lge |maemo|midp|mmp|mobile.+firefox|netfront|opera m(ob|in)i|palm( os)?|phone|p(ixi|re)\/|plucker|pocket|psp|series(4|6)0|symbian|treo|up\.(browser|link)|vodafone|wap|windows (ce|phone)|xda|xiino/i;
my $re_a_inclTablets = qr/(android|bb\d+|meego).+mobile|avantgo|bada\/|blackberry|blazer|compal|elaine|fennec|hiptop|iemobile|ip(hone|od)|iris|kindle|lge |maemo|midp|mmp|mobile.+firefox|netfront|opera m(ob|in)i|palm( os)?|phone|p(ixi|re)\/|plucker|pocket|psp|series(4|6)0|symbian|treo|up\.(browser|link)|vodafone|wap|windows (ce|phone)|xda|xiino|android|ipad|playbook|silk/i;
my $re_b             = qr/1207|6310|6590|3gso|4thp|50[1-6]i|770s|802s|a wa|abac|ac(er|oo|s\-)|ai(ko|rn)|al(av|ca|co)|amoi|an(ex|ny|yw)|aptu|ar(ch|go)|as(te|us)|attw|au(di|\-m|r |s )|avan|be(ck|ll|nq)|bi(lb|rd)|bl(ac|az)|br(e|v)w|bumb|bw\-(n|u)|c55\/|capi|ccwa|cdm\-|cell|chtm|cldc|cmd\-|co(mp|nd)|craw|da(it|ll|ng)|dbte|dc\-s|devi|dica|dmob|do(c|p)o|ds(12|\-d)|el(49|ai)|em(l2|ul)|er(ic|k0)|esl8|ez([4-7]0|os|wa|ze)|fetc|fly(\-|_)|g1 u|g560|gene|gf\-5|g\-mo|go(\.w|od)|gr(ad|un)|haie|hcit|hd\-(m|p|t)|hei\-|hi(pt|ta)|hp( i|ip)|hs\-c|ht(c(\-| |_|a|g|p|s|t)|tp)|hu(aw|tc)|i\-(20|go|ma)|i230|iac( |\-|\/)|ibro|idea|ig01|ikom|im1k|inno|ipaq|iris|ja(t|v)a|jbro|jemu|jigs|kddi|keji|kgt( |\/)|klon|kpt |kwc\-|kyo(c|k)|le(no|xi)|lg( g|\/(k|l|u)|50|54|\-[a-w])|libw|lynx|m1\-w|m3ga|m50\/|ma(te|ui|xo)|mc(01|21|ca)|m\-cr|me(rc|ri)|mi(o8|oa|ts)|mmef|mo(01|02|bi|de|do|t(\-| |o|v)|zz)|mt(50|p1|v )|mwbp|mywa|n10[0-2]|n20[2-3]|n30(0|2)|n50(0|2|5)|n7(0(0|1)|10)|ne((c|m)\-|on|tf|wf|wg|wt)|nok(6|i)|nzph|o2im|op(ti|wv)|oran|owg1|p800|pan(a|d|t)|pdxg|pg(13|\-([1-8]|c))|phil|pire|pl(ay|uc)|pn\-2|po(ck|rt|se)|prox|psio|pt\-g|qa\-a|qc(07|12|21|32|60|\-[2-7]|i\-)|qtek|r380|r600|raks|rim9|ro(ve|zo)|s55\/|sa(ge|ma|mm|ms|ny|va)|sc(01|h\-|oo|p\-)|sdk\/|se(c(\-|0|1)|47|mc|nd|ri)|sgh\-|shar|sie(\-|m)|sk\-0|sl(45|id)|sm(al|ar|b3|it|t5)|so(ft|ny)|sp(01|h\-|v\-|v )|sy(01|mb)|t2(18|50)|t6(00|10|18)|ta(gt|lk)|tcl\-|tdg\-|tel(i|m)|tim\-|t\-mo|to(pl|sh)|ts(70|m\-|m3|m5)|tx\-9|up(\.b|g1|si)|utst|v400|v750|veri|vi(rg|te)|vk(40|5[0-3]|\-v)|vm40|voda|vulc|vx(52|53|60|61|70|80|81|83|85|98)|w3c(\-| )|webc|whit|wi(g |nc|nw)|wmlb|wonu|x700|yas\-|your|zeto|zte\-/i;

sub call {
	my ($self, $env) = @_;

	my $key = defined( $self->env_key ) ? $self->env_key : 'mobile_client';

	if ( $self->tablets_as_mobile ) {
		if ( $env->{'HTTP_USER_AGENT'} =~ $re_a_inclTablets or substr( $env->{'HTTP_USER_AGENT'}, 0, 4 ) =~ $re_b ) {
			$env->{$key} = 1;
		}
		else {
			$env->{$key} = 0;
		}
	}
	else {
		if ( $env->{'HTTP_USER_AGENT'} =~ $re_a_noTablets or substr( $env->{'HTTP_USER_AGENT'}, 0, 4 ) =~ $re_b ) {
			$env->{$key} = 1;
		}
		else {
			$env->{$key} = 0;
		}
	}

	return $self->app->($env);
}

1;



=pod

=head1 NAME

Plack::Middleware::DetectMobileBrowsers - Automatically set a flag in the environment if a mobile client is detected

=head1 VERSION

version 0.03

=head1 SYNOPSIS

  use Plack::Builder;

  my $app = sub { ... } # as usual

  builder {
      enable 'DetectMobileBrowsers';
	  # or: enable 'DetectMobileBrowsers', env_key => 'mobileDevice';
	  # or: enable 'DetectMobileBrowsers', tablets_as_mobile => 1;
      $app;
  };

  # ... and later ...
  
  if ( $yourApp->theEnv->{'mobile_client'} ) {
      # ... do something ...
  }

=head1 DESCRIPTION

This Plack middleware uses the regular expression provided by 
L<http://detectmobilebrowsers.com/> to analyse the C<User-Agent> HTTP
header and to set an environment flag to either a true or false value 
depending on the detection of a mobile client device.

The default name of the flag in the environment is C<mobile_client>,
but this can be customized by setting the C<env_key> option when 
enabling this middleware.

It might make sense to use C<psgix.mobile_client> by default instead,
but the PSGI spec states that the "'psgix.' prefix is reserved for 
officially blessed extensions" - which does not apply to this module.
You may, however, set the key to C<psgix.mobile_client> yourself
by using the C<env_key> option mentioned before.

=encoding utf-8

=head1 REGEX VERSION

B<2013-09-09>

=head1 CONFIGURATION

You may specify the following option when enabling the middleware:

=over 4

=item C<env_key>

Set the name of the entry in the environment hash.

=item C<tablets_as_mobile>

Determines if tablets are considered to be mobile devices.
By default they are not; set this param to a true value to change
the default behaviour.

=back

=head1 SEE ALSO

L<Plack>, L<Plack::Middleware>, L<http://detectmobilebrowsers.com/>

=head1 AUTHOR

Heiko Jansen <hjansen@cpan.org>

=head1 COPYRIGHT AND LICENSE

This software is copyright (c) 2013 by Heiko Jansen.

This is free software; you can redistribute it and/or modify it under
the same terms as the Perl 5 programming language system itself.

=cut


__END__

