MooseX::Role::Parameterized(3pm)

NAME
MooseX::Role::Parameterized - Moose roles with composition parameters

VERSION
version 1.11

SYNOPSIS
    package Counter;
    use MooseX::Role::Parameterized;

    parameter name => (
        isa      => 'Str',
        required => 1,
    );

    role {
        my $p = shift;

        my $name = $p->name;

        has $name => (
            is      => 'rw',
            isa     => 'Int',
            default => 0,
        );

        method "increment_$name" => sub {
            my $self = shift;
            $self->$name($self->$name + 1);
        };

        method "reset_$name" => sub {
            my $self = shift;
            $self->$name(0);
        };
    };

    package MyGame::Weapon;
    use Moose;

    with Counter => { name => 'enchantment' };

    package MyGame::Wand;
    use Moose;

    with Counter => { name => 'zapped' };

DESCRIPTION
Your parameterized role consists of two new things: parameter declarations and a "role" block.

Parameters are declared using the "parameter" keyword which very much resembles "has" in Moose. You can use any option that "has" in Moose accepts. The default value for the "is" option is "ro" as that's a very common case. Use "is => 'bare'" if you want no accessor. These parameters will get their values when the consuming class (or role) uses "with" in Moose. A parameter object will be constructed with these values, and passed to the "role" block.

The "role" block then uses the usual Moose::Role keywords to build up a role. You can shift off the parameter object to inspect what the consuming class provided as parameters. You use the parameters to customize your role however you wish.

There are many possible implementations for parameterized roles (hopefully with a consistent enough API); I believe this to be the easiest and most flexible design. Coincidentally, Pugs originally had an eerily similar design.

See MooseX::Role::Parameterized::Extending for some tips on how to extend this module.

  Why a parameters object?
I've been asked several times "Why use a parameter object and not just a parameter hashref? That would eliminate the need to explicitly declare your parameters."

The benefits of using an object are similar to the benefits of using Moose. You get an easy way to specify lazy defaults, type constraint, delegation, and so on. You get to use MooseX modules.

MooseX::Role::Parameterized::Tutorial
Stop! If you're new here, please read MooseX::Role::Parameterized::Tutorial for a much gentler introduction.

You also get the usual introspective and intercessory abilities that come standard with the metaobject protocol. Ambitious users should be able to add traits to the parameters metaclass to further customize behavior. Please let me know if you're doing anything viciously complicated with this extension. :)

CAVEATS
You must use this syntax to declare methods in the role block: "method NAME => sub { ... };". This is due to a limitation in Perl. In return though you can use parameters in your methods!

SEE ALSO
<http://sartak.org/2009/01/parametric-roles-in-perl-5.html>

<http://sartak.org/2009/05/the-design-of-parameterized-roles.html>

<http://stevan-little.blogspot.com/2009/07/thoughts-on-parameterized-roles.html>

<http://perldition.org/articles/Parameterized%20Roles%20with%20MooseX::Declare.pod>

<http://www.modernperlbooks.com/mt/2011/01/the-parametric-role-of-my-mvc-plugin-system.html>

<http://jjnapiorkowski.typepad.com/modern-perl/2010/08/parameterized-roles-and-method-traits-redo.html>

<http://sartak.org/talks/yapc-asia-2009/(parameterized)-roles/>

<https://github.com/SamuraiJack/JooseX-Role-Parameterized> - this extension ported to JavaScript's Joose

SUPPORT
Bugs may be submitted through the RT bug tracker <https://rt.cpan.org/Public/Dist/Display.html?Name=MooseX-Role-Parameterized> (or bug-MooseX-Role-Parameterized@rt.cpan.org <mailto:bug-MooseX-Role-Parameterized@rt.cpan.org>).

There is also a mailing list available for users of this distribution, at <http://lists.perl.org/list/moose.html>.

There is also an irc channel available for users of this distribution, at "#moose" on "irc.perl.org" <irc://irc.perl.org/#moose>.

AUTHOR
Shawn M Moore <code@sartak.org>

CONTRIBUTORS

•   Karen Etheridge <ether@cpan.org>

•   Dave Rolsky <autarch@urth.org>

•   Jesse Luehrs <doy@tozt.net>

•   Oliver Charles <oliver.g.charles@googlemail.com>

•   Yuval Kogman <nothingmuch@woobling.org>

•   Robert 'phaylon' Sedlacek <rs@474.at>

•   Florian Ragwitz <rafl@debian.org>

•   Mark Fowler <mark@twoshortplanks.com>

•   Chris Weyl <cweyl@alumni.drew.edu>

•   Csson <erik.carlsson@live.com>

•   Andy Jack <github@veracity.ca>

•   Ricardo Signes <rjbs@cpan.org>

•   Todd Hepler <thepler@employees.org>

COPYRIGHT AND LICENSE
This software is copyright (c) 2008 by Shawn M Moore.

This is free software; you can redistribute it and/or modify it under the same terms as the Perl 5 programming language system itself.