#!/bin/csh -f
#
# A script to make appropriate tar-files
#
# Usage: make_tar [tape_device]
#

if ( $#argv >= 1 ) then
  set tapedev=$1
  mt -t $tapedev rewind || exit 1
else
  set tapedev=spring93.tar
  if ( -f $tapedev ) then
    echo "File '$tapedev' already exists."
    exit 1
  endif
endif

echo "Tape device or file to be used: $tapedev"

set ds=`du -sk doc.txt install make_tar lib tmp CSCSUITE_2 PARALLEL/DM MISC | awk 'BEGIN {a=0} {a=a+$1} END{print a}'`

echo ">>>For unloaded files the disk space comsumption is approximately ${ds} KBytes"

echo "Creating 'CSCSUITE_2.tar' ..."
tar cf CSCSUITE_2.tar  CSCSUITE_2

echo "Creating 'PARALLEL_DM.tar' ..."

set thisdir=`pwd`
set prefix=PARALLEL/DM
set progs="COMMS1 MD1 PDE1 QCD1"

foreach PROG ( $progs ) 
  set M4="$prefix/$PROG/src/m4"
  #
  # Remove files under m4-dir and their symbolic links
  #
  if ( -d $M4 ) then
    cd $M4
    set genfiles=`ls *.f`
    foreach FILE ( $genfiles )
      /bin/rm -f ../$FILE
    end
    cd $thisdir
    /bin/rm -rf $M4
  endif
end
tar cf PARALLEL_DM.tar PARALLEL/DM

echo "Creating 'MISC.tar' ..."
tar cf MISC.tar        MISC

compress -v CSCSUITE_2.tar PARALLEL_DM.tar MISC.tar

echo "Creating tape/file '$tapedev' ..."
chmod u+x install
tar cvf $tapedev doc.txt install make_tar lib tmp CSCSUITE_2.tar.Z PARALLEL_DM.tar.Z MISC.tar.Z

chmod u-x install

/bin/rm -rf CSCSUITE_2.tar.Z PARALLEL_DM.tar.Z MISC.tar.Z

exit 0

