/*
 * Copyright (C) 2009 Chase Douglas
 *
 * This program is free software; you can redistribute it and/or modify
 * it under the terms of the GNU General Public License version 2 as published
 * by the Free Software Foundation.
 *
 * This program is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU General Public License for more details.
 *
 * You should have received a copy of the GNU General Public License along
 * with this program; if not, write to the Free Software Foundation, Inc.,
 * 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
 *
 * In addition, as a special exception, the copyright holders give
 * permission to link the code of portions of this program with the
 * OpenSSL library under certain conditions as described in each
 * individual source file, and distribute linked combinations
 * including the two.
 * You must obey the GNU General Public License in all respects
 * for all of the code used other than OpenSSL.  If you modify
 * file(s) with this exception, you may extend this exception to your
 * version of the file(s), but you are not obligated to do so.  If you
 * do not wish to do so, delete this exception statement from your
 * version.
 */

#include <QHostInfo>

#import <Foundation/Foundation.h>
#import <SystemConfiguration/SCDynamicStoreCopySpecific.h>

#include "MacBroadcaster.h"

@interface broadcasterDelegate : NSObject <NSNetServiceDelegate> {}
@end

@implementation broadcasterDelegate
- (void)netService:(NSNetService *)sender didNotPublish:(NSDictionary *)errorDict {
    qWarning("Failed to publish service over bonjour (domain: %d, error: %d)", [[errorDict objectForKey:NSNetServicesErrorDomain] intValue], [[errorDict objectForKey:NSNetServicesErrorCode] intValue]);
}
@end

MacBroadcaster::MacBroadcaster(quint16 port) :
    stop(FALSE) {
    NSString *name = [[NSString alloc] initWithFormat:@"%@'s desktop on %s", NSFullUserName(), QHostInfo::localHostName().toAscii().data()];
        
    netService = [[NSNetService alloc] initWithDomain:@"" type:@"_rinput._tcp" name:name port:port];
    
    [name release];
    
    netService.delegate = [[broadcasterDelegate alloc] init];
}

void MacBroadcaster::run() {
    runLoop = [NSRunLoop currentRunLoop];
    [netService scheduleInRunLoop:runLoop forMode:NSDefaultRunLoopMode];
    [netService publish];
    while (!stop && [runLoop runMode:NSDefaultRunLoopMode beforeDate:[NSDate distantFuture]]);
}

MacBroadcaster::~MacBroadcaster() {
    stop = TRUE;
    [netService stop];
    [netService removeFromRunLoop:runLoop forMode:NSDefaultRunLoopMode];
    [netService.delegate release];
    [netService release];
}
