NAME

    Mojo::SQLite - A tiny Mojolicious wrapper for SQLite

SYNOPSIS

      use Mojo::SQLite;
    
      # Create a table
      my $sql = Mojo::SQLite->new('test.db');
      $sql->db->query('create table names (id integer primary key autoincrement, name text)');
    
      # Insert a few rows
      my $db = $sql->db;
      $db->query('insert into names (name) values (?)', 'Sara');
      $db->query('insert into names (name) values (?)', 'Stefan');
    
      # Insert more rows in a transaction
      eval {
        my $tx = $db->begin;
        $db->query('insert into names (name) values (?)', 'Baerbel');
        $db->query('insert into names (name) values (?)', 'Wolfgang');
        $tx->commit;
      };
      say $@ if $@;
    
      # Insert another row and return the generated id
      $db->query('insert into names (name) values (?)', 'Daniel');
      say $db->query('select last_insert_rowid() as id')->hash->{id};
    
      # Select one row at a time
      my $results = $db->query('select * from names');
      while (my $next = $results->hash) {
        say $next->{name};
      }
    
      # Select all rows
      $db->query('select * from names')
        ->hashes->map(sub { $_->{name} })->join("\n")->say;

DESCRIPTION

    Mojo::SQLite is a tiny wrapper around DBD::SQLite that makes SQLite
    <https://www.sqlite.org/> a lot of fun to use with the Mojolicious
    <https://mojolico.us> real-time web framework.

    Database and statement handles are cached automatically, so they can be
    reused transparently to increase performance. And you can handle
    connection timeouts gracefully by holding on to them only for short
    amounts of time.

      use Mojolicious::Lite;
      use Mojo::SQLite;
    
      helper sqlite =>
        sub { state $sql = Mojo::SQLite->new('file:///home/fred/data.db') };
    
      get '/' => sub {
        my $c  = shift;
        my $db = $c->sqlite->db;
        $c->render(json => $db->query('select datetime("now","localtime") as time')->hash);
      };
    
      app->start;

    All I/O and queries are performed synchronously. However, the
    "Write-Ahead Log" journal is enabled for all connections, allowing
    multiple processes to read and write concurrently to the same database
    file (but only one can write at a time). See http://sqlite.org/wal.html
    for more information.

      # Performed concurrently
      my $pid = fork || die $!;
      say $sql->db->query('select datetime("now","localtime") as time')->hash->{time};
      exit unless $pid;

    All cached database handles will be reset automatically if a new
    process has been forked, this allows multiple processes to share the
    same Mojo::SQLite object safely.

    While passing a file path of :memory: (or a custom "dsn" with
    mode=memory) will create a temporary database, in-memory databases
    cannot be shared between connections, so subsequent calls to "db" may
    return connections to completely different databases. For a temporary
    database that can be shared between connections and processes, pass a
    file path of :temp: to store the database in a temporary file (this is
    the default).

EVENTS

    Mojo::SQLite inherits all events from Mojo::EventEmitter and can emit
    the following new ones.

 connection

      $sql->on(connection => sub {
        my ($sql, $dbh) = @_;
        ...
      });

    Emitted when a new database connection has been established.

ATTRIBUTES

    Mojo::SQLite implements the following attributes.

 dsn

      my $dsn = $sql->dsn;
      $sql    = $sql->dsn('dbi:SQLite:uri=file:foo.db');

    Data source name, defaults to a temporary file.

 max_connections

      my $max = $sql->max_connections;
      $sql    = $sql->max_connections(3);

    Maximum number of idle database handles to cache for future use,
    defaults to 5.

 migrations

      my $migrations = $sql->migrations;
      $sql           = $sql->migrations(Mojo::SQLite::Migrations->new);

    Mojo::SQLite::Migrations object you can use to change your database
    schema more easily.

      # Load migrations from file and migrate to latest version
      $sql->migrations->from_file('/home/dbook/migrations.sql')->migrate;

 options

      my $options = $sql->options;
      $sql        = $sql->options({AutoCommit => 1, RaiseError => 1});

    Options for database handles, defaults to activating AutoCommit,
    AutoInactiveDestroy as well as RaiseError and deactivating PrintError.
    Note that AutoCommit and RaiseError are considered mandatory, so
    deactivating them would be very dangerous. DBD::SQLite specific option
    sqlite_unicode is also set by default.

METHODS

    Mojo::SQLite inherits all methods from Mojo::EventEmitter and
    implements the following new ones.

 db

      my $db = $sql->db;

    Get Mojo::SQLite::Database object for a cached or newly established
    database connection. The DBD::SQLite database handle will be
    automatically cached again when that object is destroyed, so you can
    handle connection timeouts gracefully by holding on to it only for
    short amounts of time.

      # Add up all the money
      say $sql->db->query('select * from accounts')
        ->hashes->reduce(sub { $a->{money} + $b->{money} });

 from_string

      $sql = $sql->from_string('file:test.db');

    Parse configuration from connection string. The optional scheme must be
    file, and the hostname must be localhost if specified.

      # Absolute filename
      $sql->from_string('file:///home/fred/data.db');
      $sql->from_string('file://localhost/home/fred/data.db');
      $sql->from_string('file:/home/fred/data.db');
      $sql->from_string('///home/fred/data.db');
      $sql->from_string('//localhost/home/fred/data.db');
      $sql->from_string('/home/fred/data.db');
    
      # Relative to current directory
      $sql->from_string('file:data.db');
      $sql->from_string('data.db');
    
      # Temporary file database (default)
      $sql->from_string(':temp:');
    
      # In-memory temporary database (single connection only)
      my $db = $sql->from_string(':memory:')->db;
    
      # Additional options
      $sql->from_string('data.db?PrintError=1&sqlite_allow_multiple_statements=1');

 new

      my $sql = Mojo::SQLite->new;
      my $sql = Mojo::SQLite->new('test.db');

    Construct a new Mojo::SQLite object and parse connection string with
    "from_string" if necessary.

      # Customize configuration further
      my $sql = Mojo::SQLite->new->dsn('dbi:SQLite:uri=file:test.db?mode=memory');

REFERENCE

    This is the class hierarchy of the Mojo::SQLite distribution.

      * Mojo::SQLite

      * Mojo::SQLite::Database

      * Mojo::SQLite::Migrations

      * Mojo::SQLite::Results

      * Mojo::SQLite::Transaction

BUGS

    Report any issues on the public bugtracker.

AUTHOR

    Dan Book, dbook@cpan.org

COPYRIGHT AND LICENSE

    Copyright 2015, Dan Book.

    This library is free software; you may redistribute it and/or modify it
    under the terms of the Artistic License version 2.0.

SEE ALSO

    Mojolicious, DBD::SQLite

