NAME
    Text::RecordParser - read record-oriented files

SYNOPSIS
      use Text::RecordParser;
      my $p = Text::RecordParser->new;
      $p->filename('foo.csv');

      # Split records on Micro$oft newlines
      $p->record_separator("\r\n");

      # Split fields on tabs
      $p->field_separator("\t");

      # Use the fields in the first line as column names
      $p->bind_header;

      # Get a list of the header fields (in order)
      my @columns = $p->field_list;

      # Extract a particular field from the next row
      my ( $name, $age ) = $p->extract( qw[name age] );

      # Return all the fields from the next row
      my @fields = $p->fetchrow_array;

      # Return all the fields from the next row as a hashref
      my $record = $p->fetchrow_hashref;
      print $record->{'name'};

      # Get all data as arrayref of arrayrefs
      my $data = $p->fetchall_arrayref;

      # Get all data as arrayref of hashrefs
      my $data = $p->fetchall_arrayref( { Columns => {} } );

      # Get all data as hashref of hashrefs
      my $data = $p->fetchall_hashref('name');

DESCRIPTION
    This module is for reading record-oriented data. The most common example
    have records separated by newlines ("\n" or "\r\n") and fields separated
    by commas or tabs, but this module aims to provide a consistent
    interface for handling sequential records in a file however they may be
    delimited. Typically this data lists the fields in the first line of the
    file, in which case you should call "bind_headers" to bind the field
    name. If the first line contains data, you can still bind your own field
    names via "bind_fields". Either way, you can then use many methods to
    get at the data as arrays or hashes.

    Many of the methods were shamelessly stolen from DBI and the original
    inspiration for this module, Text::xSV by Benjamin Tilly.

METHODS
  new
    This is the constructor. It takes a hash of optional arguments. Each
    argument can also be set through the method of the same name.

    * filename
        The path to the file being read. If the filename is passed and the
        fh is not, then it will open a filehandle on that file and sets "fh"
        accordingly.

    * fh
        The filehandle of the file to read.

    * field_separator
        The field separator (default is comma).

    * record_separator
        The record separator (default is newline).

    * field_filter
        A callback applied to all the fields as they are read.

    * header_filter
        A callback applied to the column names.

  bind_fields
    Takes an array of field names, memorizes the field positions for later
    use. "bind_headers" is preferred.

      $p->bind_fields( qw[ name rank serial_number ] );

  bind_header
    Takes the fields from the next row under the cursor and assigns the
    field names to the values. Usually you would call this immediately after
    opening the file in order to bind the field names in the first row.

      $p->bind_header;
      my $name = $p->extract('name');

  extract
    Extracts a list of fields out of the last row read. The field names must
    correspond to the field names bound either via "bind_fields" or
    "bind_header".

      my ( $foo, $bar, $baz ) = $p->extract( qw[ foo bar baz ] );

  fetchrow_array
    Reads a row from the file and returns an array or (arrayref) of the
    fields.

      my @values = $p->fetchrow_array;

  fetchrow_hashref
    Reads a line of the file and returns it as a hash reference. The keys of
    the hashref are the field names bound via "bind_fields" or
    "bind_header".

      my $record = $p->fetchrow_hashref;
      print "Name = ", $record->{'name'}, "\n";

  fetchall_arrayref
    Like DBI's fetchall_arrayref, returns an arrayref of arrayrefs. Also
    accepts optional "{ Columns => {} }" argument to return an arrayref of
    hashrefs.

      my $records = $p->fetchall_arrayref;
      for my $record ( @$records ) {
          print "Name = ", $record->[0], "\n";
      }

      my $records = $p->fetchall_arrayref( { Columns => {} } );
      for my $record ( @$records ) {
          print "Name = ", $record->{'name'}, "\n";
      }

  fetchall_hashref
    Like DBI's fetchall_hashref.

      my $records = $p->fetchall_hashref('id');
      for my $id ( keys %$records ) {
          my $record = $records->{ $id };
          print "Name = ", $record->{'name'}, "\n";
      }

  fh
    Gets or sets the filehandle of the file being read.

      open my $fh, "<./data.csv";
      $p->fh( $fh );

  field_compute
    A callback applied to the fields identified by position (or field name
    if "bind_fields" or "bind_headers" was called). If data looks like this:

      parent    children
      Mike      Greg,Peter,Bobby
      Carol     Marcia,Jane,Cindy

    You could split the "children" field into an array reference with the
    values like so:

      $p->field_compute( 'children', sub { [ split /,/, shift() ] } );

    The callback will be passed two arguments:

    1   The current field

    2   A reference to all the other fields, either as an array or hash
        reference, depending on the method which you called.

    The field position or name doesn't actually have to exist, which means
    you could create new, computed fields on-the-fly. E.g., if you data
    looks like this:

        1,3,5
        32,4,1
        9,5,4

    You could write a field_compute like this:

        $p->field_compute( 3,
            sub {
                my ( $cur, $others ) = @_;
                my $sum;
                $sum += $_ for @$others;
                return $sum;
            }
        );

    Field "3" will be created as the sum of the other fields. This allows
    you to further write:

        my $data = $p->fetchall_arrayref;
        for my $rec ( @$data ) {
            print "$rec->[0] + $rec->[1] + $rec->[2] = $rec->[3]\n";
        }

    Prints:

        1 + 3 + 5 = 9
        32 + 4 + 1 = 37
        9 + 5 + 4 = 18

  field_filter
    A callback which is applied to each field. Here's an example that
    removes the leading and trailing spaces from each field:

      $p->field_filter( sub { $_ = shift; s/^\s+|\s+$//g; $_ } );

  field_list
    Returns the fields bound via "bind_fields" (or "bind_header").

      $p->bind_fields( qw[ foo bar baz ] );
      my @fields = $p->field_list;
      print join(', ', @fields); # prints "foo, bar, baz"

  field_positions
    Returns the field positions bound via "bind_fields" (or "bind_header").

  field_separator
    Gets and sets the token to use as the field delimiter. The default is a
    comma.

      $p->field_separator("\t");     # splits fields on tabs
      $p->field_separator('::');     # splits fields on double colons
      my $sep = $p->field_separator; # returns the current separator

  filename
    Gets or sets the complete path to the file to be read. If a file is
    already opened, then the handle on it will be closed and a new one
    opened on the new file.

      $p->filename('/path/to/file.dat');

  header_filter
    A callback applied to column header names. Here's an example that
    collapses spaces into a single underscore and lowercases the letters:

      $p->header_filter( sub { $_ = shift; s/\s+/_/g; lc $_ } );

  record_separator
    Gets and sets the token to use as the record separator. The default is a
    newline ("\n").

    To read a file that looks like this:

      field1
      field2
      field3
      // 
      data1
      data2
      data3
      //

    Set the record and field separators like so:

      $p->record_separator("\n//\n");
      $p->field_separator("\n");

AUTHOR
    Ken Y. Clark <kclark@cshl.org>

COPYRIGHT
    Copyright (c) 2003 Ken Y. Clark

    This library is free software; you can redistribute it and/or modify it
    under the same terms as Perl itself.

BUGS
    Please use http://rt.cpan.org/ for reporting bugs.

