#!/usr/local/bin/perl -w
# $Id: perldig,v 1.3 1997/02/13 23:22:35 mfuhr Exp $

=head1 NAME

perldig - Perl script to perform DNS queries

=head1 SYNOPSIS

C<perldig> [ C<@>I<nameserver> ] I<name> [ I<type> [ I<class> ] ]

=head1 DESCRIPTION

Performs a DNS query on the given name.  The record type
and class can also be specified; if left blank they default
to A and IN.

=head1 AUTHOR

Michael Fuhr <mfuhr@dimensional.com>

=head1 SEE ALSO

L<perl(1)>, L<check_soa>, L<check_zone>, L<mx>, L<Net::DNS>

=cut

use strict;

use File::Basename;
use Net::DNS;

my $res = new Net::DNS::Resolver;
if (@ARGV && ($ARGV[0] =~ /^@/)) {
	my $nameserver = shift;
	$nameserver =~ s/^@//;
	$res->nameservers($nameserver);
}

die "Usage: ", basename($0), " [ \@nameserver ] name [ type [ class ] ]\n"
	unless (@ARGV >= 1) && (@ARGV <= 3);

my ($name, $type, $class) = @ARGV;
$type  ||= "A";
$class ||= "IN";

if (uc($type) eq "AXFR") {
	my @zone = $res->axfr($name, $class);
	if (defined(@zone) && @zone) {
		foreach (@zone) {
			$_->print;
		}
	}
	else {
		print "zone transfer failed: ", $res->errorstring, "\n";
	}
}
else {
	my $answer = $res->send($name, $type, $class);
	if (defined($answer)) {
		$answer->print;
	}
	else {
		print "query failed: ", $res->errorstring, "\n";
	}
}
