#!/usr/bin/env perl

use warnings;
use strict;
use File::Slurp;
use File::Find;
use Getopt::Attribute;


our $VERSION = '0.07';


our $version : Getopt(version|v=s);
our $dry_run : Getopt(dry_run|n);
our @dir     : Getopt(dir|d=s);

die "version?\n" unless defined $version;
die "version must be \\d\\.\\d\\d\n" unless $version =~ /^\d\.\d\d$/;

$dry_run = 0 unless defined $dry_run;
@dir = ('.') unless @dir;
@dir = grep { -d && -r } @dir;

find(sub {
    return unless -f && -r;
    my $contents = read_file($_);
    if ($contents =~ s/(\$VERSION\s*=\s*([\'\"]))(.+?)\2/$1$version$2/) {
        warn "$_: set version $version (previously $3)\n";
        warn $contents if $dry_run;
        return if $dry_run;
        open my $fh, '>', $_ or die "can't open $_ for writing: $!\n";
        print $fh $contents;
        close $fh or die "can't close $_: $!\n";
    } else {
        warn "$_: no \$VERSION line\n";
    }
}, @dir);


__END__

=head1 NAME

Dist::Joseki - tools for the prolific module author

=head1 SYNOPSIS

None yet (see below).

=head1 DESCRIPTION

None yet. This is an early release; fully functional, but undocumented. The
next release will have more documentation.

=head1 TAGS

If you talk about this module in blogs, on del.icio.us or anywhere else,
please use the C<distjoseki> tag.

=head1 BUGS AND LIMITATIONS

No bugs have been reported.

Please report any bugs or feature requests to
C<bug-dist-joseki@rt.cpan.org>, or through the web interface at
L<http://rt.cpan.org>.

=head1 INSTALLATION

See perlmodinstall for information and options on installing Perl modules.

=head1 AVAILABILITY

The latest version of this module is available from the Comprehensive Perl
Archive Network (CPAN). Visit <http://www.perl.com/CPAN/> to find a CPAN
site near you. Or see <http://www.perl.com/CPAN/authors/id/M/MA/MARCEL/>.

=head1 AUTHOR

Marcel GrE<uuml>nauer, C<< <marcel@cpan.org> >>

=head1 COPYRIGHT AND LICENSE

Copyright 2007 by Marcel GrE<uuml>nauer

This library is free software; you can redistribute it and/or modify
it under the same terms as Perl itself.

=cut

