Test::LectroTest::Compat(3p)

NAME
Test::LectroTest::Compat - Use LectroTest property checks in a Test::Simple world

VERSION
version 0.5001

SYNOPSIS
    #!/usr/bin/perl -w

    use MyModule;  # contains code we want to test
    use Test::More tests => 2;
    use Test::LectroTest::Compat;

    # property specs can now use Test::Builder-based
    # tests such as Test::More's cmp_ok()

    my $prop_nonnegative = Property {
        ##[ x <- Int, y <- Int ]##
        cmp_ok(MyModule::my_function( $x, $y ), '>=', 0);
    }, name => "my_function output is non-negative" ;

    # and we can now check whether properties hold
    # as a Test::Builder-style test that integrates
    # with other T::B tests

    holds( $prop_nonnegative );   # test whether prop holds
    cmp_ok( 0, '<', 1, "trivial 0<1 test" );  # a "normal" test

DESCRIPTION
This module lets you use mix LectroTest property checking with other popular Test::* modules. With it, you can use is()- and ok()-style assertions from Test::* modules within your LectroTest property specifications and you can check LectroTest properties as part of a Test::Simple or Test::More test plan. (You can actually take advantage of any module based on Test::Builder, not just Test::Simple and Test::More.)

The module exports a single function "holds" which is described below.

  holds(property, opts...)
    holds( $prop_nonnegative );  # check prop_nonnegative

    holds( $prop_nonnegative, trials => 100 );

    holds(
        Property {
            ##[ x <- Int ]##
            my_function2($x) < 0;
        }, name => "my_function2 is non-positive"
    );

Checks whether the given property holds.

When called, this method creates a new Test::LectroTest::TestRunner, asks the TestRunner to check the property, and then reports the result to Test::Builder, which in turn reports to you as part of a typical Test::Simple- or Test::More-style test plan. Any options you provide to "holds" after the property will be passed to the "TestRunner" so you can change the number of trials to run and so on. (See the docs for "new" in Test::LectroTest::TestRunner for the complete list of options.)

TESTING FOR REGRESSIONS AND CORNER CASES
LectroTest can record failure-causing test cases to a file, and it can play those test cases back as part of its normal testing strategy. The easiest way to take advantage of this feature is to set the regressions parameter when you "use" this module:

    use Test::LectroTest::Compat
        regressions => "regressions.txt";

This tells LectroTest to use the file "regressions.txt" for both recording and playing back failures. If you want to record and play back from separate files, or want only to record or play back, use the record_failures and/or playback_failures options:

    use Test::LectroTest::Compat
        playback_failures => "regression_suite_for_my_module.txt",
        record_failures   => "failures_in_the_field.txt";

See Test::LectroTest::RegressionTesting for more.

NOTE: If you pass any of the recording or playback parameters to Test::LectroTest::Compat, you must have version 0.3500 or greater of LectroTest installed. Module authors, update your modules' build dependencies accordingly.

BUGS
In order to integrate with the Test::Builder testing harness (whose underlying testing model is somewhat incompatible with the needs of random trial-based testing) this module redefines two Test::Builder functions (ok() and diag()) for the duration of each property check.

SEE ALSO
For a gentle introduction to LectroTest, see Test::LectroTest::Tutorial. Also, the slides from my LectroTest talk for the Pittsburgh Perl Mongers make for a great introduction. Download a copy from the LectroTest home (see below).

Test::LectroTest::RegressionTesting explains how to test for regressions and corner cases using LectroTest.

Test::LectroTest::Property explains in detail what you can put inside of your property specifications.

Test::LectroTest::Generator describes the many generators and generator combinators that you can use to define the test or condition space that you want LectroTest to search for bugs.

Test::LectroTest::TestRunner describes the objects that check your properties and tells you how to turn their control knobs. You'll want to look here if you're interested in customizing the testing procedure.

Test::Simple and Test::More explain how to do simple case-based testing in Perl.

Test::Builder is the test harness upon which this module is built.

AUTHOR
Tom Moertel (tom@moertel.com)

INSPIRATION
The LectroTest project was inspired by Haskell's QuickCheck module by Koen Claessen and John Hughes: http://www.cs.chalmers.se/~rjmh/QuickCheck/.

COPYRIGHT and LICENSE
Copyright (c) 2004-13 by Thomas G Moertel. All rights reserved.

This program is free software; you can redistribute it and/or modify it under the same terms as Perl itself.