#!perl -w

# RSS2Leafnode -- copy RSS feeds to a local news spool

# Copyright 2007, 2008, 2009, 2010 Kevin Ryde
#
# This file is part of RSS2Leafnode.
#
# RSS2Leafnode is free software; you can redistribute it and/or modify it
# under the terms of the GNU General Public License as published by the Free
# Software Foundation; either version 3, or (at your option) any later
# version.
#
# RSS2Leafnode is distributed in the hope that it will be useful, but
# WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
# or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
# for more details.
#
# You should have received a copy of the GNU General Public License along
# with RSS2Leafnode.  If not, see <http://www.gnu.org/licenses/>.

use 5.010;
use strict;
use warnings;
use App::RSS2Leafnode;

use Encode;           # for Encode::PERLQQ
use PerlIO::encoding; # for fallback
# version 0.06 for bug fix of a struct size for perl 5.10 (there's some
# fragile duplication)
use PerlIO::locale 0.06;

our $VERSION = 35;

# locale encoding conversion on the tty, wide-chars everywhere internally
# for instance $subject from an item might be wide chars printed when --verbose
{ no warnings 'once';
  local $PerlIO::encoding::fallback = Encode::PERLQQ; # \x{1234} style
  (binmode (STDOUT, ':locale') && binmode (STDERR, ':locale'))
    or die "Cannot set :encoding on stdout/stderr: $!\n";
}

my $r2l = App::RSS2Leafnode->new;
exit $r2l->command_line;

__END__

=for stopwords rss2leafnode rss leafnode NNTP config leafnode undef charset utf-8 non-ascii charsets builtins misconfigured Eg Unrendered Google pre-releases Ryde PNG libxml multibyte codings feed's

=head1 NAME

rss2leafnode -- post RSS or Atom feeds and web pages to newsgroups

=head1 SYNOPSIS

 rss2leafnode [--options]

=head1 DESCRIPTION

RSS2Leafnode downloads RSS or Atom feeds and posts items as messages to an
NNTP news server.  It's designed to make simple text entries available in
local newsgroups, not propagating anywhere (though that's not enforced).

Desired feeds are given in a configuration file F<.rss2leafnode.conf> in
your home directory.  For example to put a feed in group "r2l.perl"

    fetch_rss ('r2l.perl', 'http://log.perl.org/atom.xml');

This is actually Perl code, so comment lines begin with C<#> and you can
write conditionals etc.  The target newsgroup must exist (see L</Leafnode>
below).  With that done, run C<rss2leafnode> as

    rss2leafnode

You can automate with C<cron> or similar.  If you do it under user C<news>
it could be just after a normal news fetch.  The C<--config> option below
lets you run different config files at different times, etc.
A sample config file is included in the RSS2Leafnode sources.

Messages are added to the news spool using NNTP "POST" commands.  When a
feed is re-downloaded any items previously added are not repeated.  Multiple
feeds can be put into a single newsgroup.  Feeds are inserted as they're
downloaded, so the first articles appear while the rest are still in
progress.

The target newsgroup can also be a C<news:> or C<nntp:> URL of a server on a
different host or a different port number if running a personal server on a
high port.

    fetch_rss('news://somehost.mydomain.org:8119/r2l.weather',
              'http://feeds.feedburner.com/PTCC');

=head2 Web Pages

Plain web pages can be downloaded too.  Each time the page changes a new
article is injected.  This is good for a latest news or status page which
don't have an RSS feed.  For example

    fetch_html ('r2l.finance,
                'http://www.baresearch.com/free/index.php?category=1');

The target can be an image or similar directly too, it's simply put into a
news message with its indicated MIME type.  How well it displays depends on
your newsreader.

The message "Subject" is the HTML C<< <title> >>, or something better from
C<URI::Title> or C<Image::ExifTool> if you've got them.  C<URI::Title> has
special cases for a few unhelpful sites and C<Image::ExifTool> can get a PNG
image title.

=head2 Re-Downloading

HTTP C<ETag> and C<Last-Modified> headers are used, if provided by the
server, to avoid re-downloading unchanged content (feeds or web pages).
Values seen from the last run are saved in a F<.rss2leafnode.status> file in
your home directory.

If you've got C<XML::RSS::Timing> then it's used for RSS C<ttl>,
C<updateFrequency>, etc from a feed.  This means the feed is not
re-downloaded until its specified update times.  Only a few feeds have
useful timing info, most merely give a C<ttl> advising for instance 5
minutes between rechecks.

With C<--verbose> the next calculated update time is printed in case you're
wondering why nothing is happening.  The easiest way to force a re-download
is to delete the F<~/.rss2leafnode.status> file.  Old status file entries
are automatically dropped if you don't fetch a particular feed for a while,
so that file should normally need no maintenance.

=head2 Leafnode

C<rss2leafnode> was originally created with the C<leafnode> program in mind,
but can be used with any server accepting posts.  It's your responsibility
to be careful where a target newsgroup propagates.  Don't make automated
postings to the world!

For leafnode see its F<README> file section "LOCAL NEWSGROUPS" on creating
local-only groups.  Basically you add a line to the
F</etc/news/leafnode/local.groups> file like

    r2l.stuff	y	My various feeds

The group name is arbitrary and the description is optional, but note it
must be a tab character between the name and the "y" and between the "y" and
any description.  "y" means posting is allowed.

=head2 Small News

The Small News "sn" program is a possible local server too.  Create groups
in it with C<snnewgroup r2l.something>.  When running C<snntpd> from
C<inetd> or similar don't forget a logger program argument on the command
line as shown in its F<INSTALL.run>, otherwise log messages from C<snntpd>
will confuse client programs, including C<Net::NNTP> as used by
C<rss2leafnode>.

=head2 Copyright

It's your responsibility to check the terms of use for any feeds or web
pages you download with C<rss2leafnode>.  Pay particular attention if
propagating or re-transmitting resulting messages.

Copyright or license statements in a feed are included in the messages under
C<X-Copyright> headers.  Unless the content is in the public domain such
copyright notices must be retained.

=head1 COMMAND LINE OPTIONS

The command line options are

=over 4

=item C<--config=/some/filename>

Read the specified configuration file instead of F<~/.rss2leafnode.conf>.

=item C<--help>

Print some brief help information.

=item C<--verbose>

Print some diagnostics about what's being done.  With C<--verbose=2> print
various technical details.

=item C<--version>

Print the program version number and exit.

=back

=head1 CONFIG OPTIONS

The following variables can be set in the configuration file

=over 4

=item $rss_get_links (default 0)

If true then download links in each item and include the content in the news
message.  For example,

    $rss_get_links = 1;
    fetch_rss ('r2l.finance',
      'http://au.biz.yahoo.com/financenews/htt/financenews.xml');

Not all feeds have interesting things at their link, but for those which do
this can make the full article ready to read immediately, instead of having
to click through from the message.

Only the immediate link target URL is retrieved.  No images within the page
are downloaded (which is often a good thing), and you'll probably have
trouble if the link uses frames (a set of HTML pages instead of just one).

=item $render (default 0)

If true then render HTML to text for the news messages.  Normally item text,
C<$rss_get_links> downloaded parts, and C<fetch_html> pages are all
presented as C<text/html>.  If your newsreader doesn't handle HTML very well
then C<$render> is a good way to see just the text.  Setting C<1> uses
C<HTML::FormatText>

    $render = 1;
    fetch_rss ('r2l.weather',
      'http://xml.weather.yahoo.com/forecastrss?p=ASXX0001&u=f');

Setting C<"WithLinks"> uses the C<HTML::FormatText::WithLinks> variant (you
must have that module) which shows HTML links as footnotes.

    $render = 'WithLinks';
    fetch_rss ('r2l.stuff',
               'http://rss.sciam.com/sciam/basic-science');

Settings C<elinks>, C<lynx> or C<w3m> dump through the respective external
program (you must have C<HTML::FormatExternal> and the program).

    $render = 'lynx';
    $rss_get_links = 1;
    fetch_rss ('r2l.sport',
               'http://fr.news.yahoo.com/rss/rugby.xml');

=item $render_width (default 60)

The number of columns to use when rendering HTML to plain text or when
wrapping Atom text.  You can set this to whatever you find easiest to read,
or any special width needed by a particular feed.

=cut

# =item $get_icon (default 0)
# 
# Download RSS/Atom icon image or HTML favicon for the C<Face> header.  This
# header is used by Gnus, and perhaps only a few other news readers.  In
# Gnus the face appears with the "From" in the article mode display on a
# graphical screen.  It can be a nice visual cue to the channel origin etc,
# but might not always be worth the extra download.
# 
#     $get_icon = 1;
#     fetch_rss ('r2l.whatsnew',
#                'http://www.archive.org/services/collection-rss.php');
# 
# C<Image::Magick> is required to convert or shrink an image.  Banner images
# much wider than high are suppressed as probably advertising and in any
# case not suited to 48x48 of the Face header specification.
# 
# For plain RSS and Atom feeds an image is normally per-channel so is the
# same for all articles from it.  C<itunes:image> can be per-item and is
# used if present.

=back

=head2 Obscure Options

=over 4

=item $rss_charset_override (default undef)

If set then force RSS content to be interpreted in this charset,
irrespective of what the document says.  See L<XML::Parser/ENCODINGS> for
the charsets supported by the parser (the F<.enc> files under
F</usr/lib/perl5/XML/Parser/Encodings/> plus some builtins).

Use this option if the document is wrong or has no charset specified and
isn't the XML default utf-8.  Usually you'll only want this for a particular
offending feed.  For example,

    # AIR is latin-1, but doesn't have a <?xml> saying that
    $rss_charset_override = 'iso-8859-1';
    fetch_rss ('r2l.finance', 'http://www.aireview.com.au/rss.php');
    $rss_charset_override = undef;

By default RSS2Leafnode attempts to cope with bad multibyte sequences by
re-coding to the feed's claimed charset.  If that works then the text will
have some substitute characters (either U+FFFD or question marks "?") and a
warning is given like

    Feed http://example.org/feed.xml
      recoded utf-8 to parse, expect substitutions for bad non-ascii
      (line 214, column 75, byte 13196)

Bad single-byte codings generally aren't detected and will just go through
to display something incorrect (eg. MS-DOS codepage 1252 used where Latin-1
is claimed).  Nose around the raw feed as necessary to see where it goes
wrong.

=item $html_charset_from_content (default 0)

If true then the charset used for C<fetch_html> content is taken from the
HTML itself, rather than the server's HTTP headers.  Normally the server
should be believed, but if a particular server is misconfigured then you can
try this.

    $html_charset_from_content = 1;
    fetch_rss ('r2l.stuff',
               'http://www.somebadserver.com/newspage.html');

=back

=head2 Variable Extent

Variables take effect from the point they're set, through to the end of the
file, or until a new setting.  The Perl C<local> feature and a braces block
can confine a setting to a particular few feeds.  Eg.

    { local $rss_get_links = 1;
      fetch_rss ('r2l.finance',
                 'http://www.debian.org/News/weekly/dwn.en.rdf');
    }

=head1 OTHER DETAILS

Non-ascii RSS and Atom text and rendered HTML text are all coded as utf-8 in
the generated messages so for non-ascii content you'll need a newsreader
which supports that.  Unrendered HTML is left in the charset the server
gave, to ensure it matches any C<< <meta http-equiv> >> in the document.  In
all cases the charset is specified in the MIME message headers or attachment
parts.  Transfer format in the message body is chosen by C<MIME::Entity>
(except for Atom base64 C<< <content> >>) which normally means
quoted-printable it there's any non-ascii or very long lines.

Links are shown for RSS and Atom C<< <link> >>, RSS C<< <enclosure> >> and
C<< <comments> >>, Atom external C<< <content> >> (except other XML feeds),
C<< <wfw:comment> >> and C<< <wiki:diff> >>.  Comments and "replies" links
are not downloaded under C<$rss_get_links> (currently).  Comment or reply
counts are shown from C<< <thr:total> >>, C<< thr:count >> and
C<< <slash:comments> >>.

Common Alerts Protocol (CAP) fields for weather alerts etc are shown if
present (eg. from the US NOAA).  This is slightly experimental but can have
more detail than just the text.

An attempt is made to repair bad XML from a feed using C<XML::Liberal> if
you have that module.  It uses C<XML::LibXML> and the C<libxml> library.
A repair can help annoying things like bad entities and may be enough to at
least see something.

Too much or too little entity escaping tends to be the most common feed
problem.  Too little can turn HTML into nested XML elements instead of text.
RSS2Leafnode extracts that as if it was XHTML, though the result is likely
to be imperfect.  Too much escaping currently ends up displaying as raw or
semi-raw HTML.  An option for extra unescaping might be possible, to at
least improve the display of a particular bad feed.

=head2 Message Headers

For interest or for reference the headers in the messages are generated
roughly as follows,

=over

=item From:

First of <author>, <dc:creator>, <dc:contributor>, <wiki:username>,
<itunes:author>, <managingEditor>, <webMaster>, <dc:publisher>,
<itunes:owner>, channel <title>.

If there's no identifiable mailbox part then C<nobody@rss2leafnode.dummy> is
added.  The channel title as a fallback is good to at least show something
about where a message came from when there's no other author identified.

=item X-From-Url:

<uri> from an Atom <author>, being the home page of the From: person.  This
is experimental.

=item Subject:

<title> or <dc:subject>.  The <dc:subject> is normally only a keyword but
might be better than nothing.

=item Date:

First present of <pubDate>, <dc:date>, <modified>, <updated>, <issued>,
<created>, <lastBuildDate>, <published>

=item Date-Received:

The date/time when C<rss2leafnode> made the message.

=item Message-ID:

First of <id>, <guid isPermaLink="true">, Yahoo <link>, <guid
isPermaLink="false"> plus feed URL, or MD5 hash of various fields plus feed
URL.

Yahoo Finance items repeated in different feeds are noticed using a special
match of the <link> in the items so that just one copy is posted.  (As of
March 2010 Yahoo's items don't offer RSS C<guid> identifiers.)

=item Keywords:

All of <category>, <itunes:category>, <cap:category>, <itunes:keywords>,
<media:keywords>, <dc:subject>.  The sub-category system of
<itunes:category> is not currently put through.

=item In-Reply-To:

<thr:in-reply-to>, turned into Message-ID style the same way as Atom <id>.
This might help thread display in a news reader, though of course only if
the parent item was downloaded too.

=item Content-Location:

The URL of a C<fetch_html()> or a C<$get_links> attachment part.  Good
newsreaders use this to resolve relative links in HTML.

=item Content-Language:

<language>, <dc:language>, xml:lang="", or HTTP response Content-Language.
xml:lang is a standard XML attribute and may be present on any element.
It's sometimes found on Atom <content> text.

=item Content-MD5:

From the corresponding HTTP header of a C<fetch_html()> or C<$get_links>
download, if present (which is almost never).

=item Importance:

=item Priority:

From common alerts protocol <cap:severity>.  Extreme and Severe are treated
as "high" importance and "urgent" priority.  These headers are supposed to
be only for X.400 inter-operation though.

A Precedence: header is not generated currently though it could get a
similar value, plus maybe "list" or "bulk" if a feed is a mailing list or
similar and if that could be identified.

=item Face:

Experimental C<$get_icons> option from item or channel <image>, <icon>,
<logo>, <itunes:image>.

=item List-Post:

Mailbox of a Google Groups mailing list feeds such as
L<http://groups.google.com/group/cake-php/feed/rss_v2_0_msgs.xml>.  This may
help post a followup to the list, depending on the newsreader.  (A followup
to an C<rss2leafnode> newsgroup will normally go nowhere.)

=item PICS-Label:

Channel <rating>.  Perhaps in the future <itunes:explicit> or <media:adult>
could be turned into a rating too.

=item X-Mailer:

"RSS2Leafnode/VERSION" added to whatever C<MIME::Entity> gives.

=item X-Copyright:

An RSS2Leafnode extension, being all of <rights>, <copyright>, <dc:license>,
<dc:rights>, <creativeCommons:license>.  See L</Copyright> above.

=item X-RSS-Url:

Originating C<fetch_rss()> feed URL downloaded.  This is handy if an item
has come out badly and want to check the raw feed.

=item X-RSS-Generator:

Channel <generator>.  This might help assign blame for bad formatting etc.

=back

=head1 BUGS

The way Message-IDs are checked on the server means the server should be
setup to keep messages for at least as long as the feed retains items.  If
that's not so then old articles will be re-posted by the next C<fetch_rss>
and will look like new articles to a newsreader.

Letting the news server track articles keeps down the amount of state
C<rss2leafnode> must maintain and means multiple users can insert a feed
without duplication, but perhaps long feeds will need further re-post
protection.

Some pre-releases of leafnode 2 have trouble with posts to local newsgroups
while a C<fetchnews> run is in progress.  The local articles don't show up
until after a subsequent further C<fetchnews>.

=head1 FILES

=over 4

=item F<~/.rss2leafnode.conf>

Configuration file.

=item F<~/.rss2leafnode.status>

Status file, recording "last modified" dates for downloads.  This can be
deleted if something bad seems to have happened to it; the next
C<rss2leafnode> run will recreate it.

=back

=head1 SEE ALSO

L<leafnode(8)>,
L<HTML::FormatText>, L<HTML::FormatText::WithLinks>, L<HTML::FormatExternal>,
L<lynx(1)>,
L<URI::Title>, L<XML::Parser>, L<XML::Liberal>

L<Plagger>, L<feed2imap(1)>, L<rss2email(1)>, L<rssdrop(1)>, L<toursst(1)>,
L<http://www.gwene.org>

=head1 HOME PAGE

L<http://user42.tuxfamily.org/rss2leafnode/index.html>

=head1 LICENSE

Copyright 2007, 2008, 2009, 2010 Kevin Ryde

RSS2Leafnode is free software; you can redistribute it and/or modify it
under the terms of the GNU General Public License as published by the Free
Software Foundation; either version 3, or (at your option) any later
version.

RSS2Leafnode is distributed in the hope that it will be useful, but WITHOUT
ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License for
more details.

You should have received a copy of the GNU General Public License along with
RSS2Leafnode.  If not, see L<http://www.gnu.org/licenses/>.

=cut
