# ex_palettelist.ppl
#
# The code in this file is part of Pyxplot
# <http://www.pyxplot.org.uk>
#
# Copyright (C) 2006-2012 Dominic Ford <coders@pyxplot.org.uk>
#               2008-2012 Ross Church
#
# $Id: ex_palettelist.ppl 1275 2012-07-23 07:35:55Z dcf21 $
#
# Pyxplot is free software; you can redistribute it and/or modify it under the
# terms of the GNU General Public License as published by the Free Software
# Foundation; either version 2 of the License, or (at your option) any later
# version.
#
# You should have received a copy of the GNU General Public License along with
# Pyxplot; if not, write to the Free Software Foundation, Inc., 51 Franklin
# Street, Fifth Floor, Boston, MA  02110-1301, USA

# ----------------------------------------------------------------------------

# This script produces a figure for the Pyxplot Users' Guide

# Call common initialisation script
reset
title = "ex_palettelist"
load "examples/fig_init.ppl"

set multiplot
set nodisplay
set texthal cent
set textval cent

bh = unit(1.3*cm)
bw = unit(2.7*cm)

pal = ["black", "red", "blue", "magenta", "cyan", "brown", "salmon", "gray", "green", "navyBlue", "periwinkle", "pineGreen", "seaGreen", "greenYellow", "orange", "carnationPink", "plum"]
palLen = pal.len()

for (i=0; i<palLen; i++)
 {
  ypos  = -floor(i/6);
  xpos  = i%6;
  col   = pal[i]
  colObj= colors[col]
  bac   = (colObj.componentsRGB().norm()>1.2) ? colors.black : colors.white
  box from bw*xpos,bh*ypos to bw*(xpos+1),bh*(ypos+1) with fillcol colObj
  text r"\parbox{5cm}{\centerline{\bf %d}\centerline{\bf %s}}"%(i+1,col) at bw*(xpos+0.5),bh*(ypos+0.5) with col bac
 }

# Now that we are finished preparing multiplot, turn display on
set display
refresh

# Call common cleanup script
load "examples/fig_end.ppl"

