# ex_polygon1.ppl
#
# The code in this file is part of Pyxplot
# <http://www.pyxplot.org.uk>
#
# Copyright (C) 2006-2012 Dominic Ford <coders@pyxplot.org.uk>
#               2008-2012 Ross Church
#
# $Id: ex_polygon2.ppl 1261 2012-07-11 21:38:05Z dcf21 $
#
# Pyxplot is free software; you can redistribute it and/or modify it under the
# terms of the GNU General Public License as published by the Free Software
# Foundation; either version 2 of the License, or (at your option) any later
# version.
#
# You should have received a copy of the GNU General Public License along with
# Pyxplot; if not, write to the Free Software Foundation, Inc., 51 Franklin
# Street, Fifth Floor, Boston, MA  02110-1301, USA

# ----------------------------------------------------------------------------

# This script produces a figure for the Pyxplot Users' Guide

# Call common initialisation script
reset
title = "ex_polygon2"
load "examples/fig_init.ppl"

# BEGIN
rotate(a) = matrix( [cos(a), -sin(a)], \
                    [sin(a),  cos(a)] )

subroutine makePolygon(Nsides, centre)
 {
  points = []
  for i=0 to Nsides
   {
    call points.append(centre + \
       rotate(i/Nsides*unit(rev)) * vector(1,0))
   }
  polygon points with fillcol gray50 col black
 }

set nodisplay ; set multiplot

set texthalign center
set textvalign top

foreach datum x,y,Nsides,name in "--"
 {
  call makePolygon(Nsides,vector(x,y))
  text name at x,y-1.25
 }
0 0 3 Triangle
3 0 4 Square
6 0 5 Pentagon
0 4 6 Hexagon
3 4 7 Heptagon
6 4 8 Octagon
END

set display ; refresh
# END

# Call common cleanup script
load "examples/fig_end.ppl"

