#! /usr/bin/sed -f
# N.B.  This is used only with GCC.  There's a bug in sed under MinGW which means
# that CRNL line endings don't work so this file must be marked as binary.
s/;#.*//
s/^IFDEF/#ifdef/
s/^ELSE/#else/
s/^ENDIF/#endif/
s/^IFNDEF/#ifndef/
# Convert macro calls.
s/CALLMACRO[ 	]*\([^ 	]*\)[ 	]*\(.*\)/	\1(\2)/
# Convert addresses of the form [eax], [eax+ebx], [eax+ebx*4] into
# (eax), (eax,ebx), (eax,ebx,4)
s/\[\([^]]*\)+\([^]]*\)\*\([^]]*\)]/(\1,\2,\3)/g
s/\[\([^]]*\)+\([^]]*\)]/(\1,\2)/g
s/\[\([^]]*\)]/(\1)/g
