!set title=Columnas y filas II

!goto $wims_read_parm

:present
 Considerar 3 matrices A,B,C. Los productos AB, BC y CA son todos válidos.
 Haciendo preguntas a elegir entre las siguientes,
 encontrar el número de $orients de la matriz $matname.
!exit

:form
 La matriz $matname tiene
 <input size=3 name=ans1> $orients.
!exit

:ans
 Crees que la matriz $matname tiene $ans1 $orients.
 !ifval $ans1=$good1
  <font color=green>Correcto</font>.
 !else
  <font color=red>Estás equivocado</font>: $matname tiene $good1 $orients.
 !endif
 !exit

:init
 storename=mat,matname,matprev,matfoll,o,orient,orients,inv,invs
 mat=!randitem 1,2,3
 matname=!item $mat of A,B,C
 matprev=!item $mat of C,A,B
 matfoll=!item $mat of B,C,A
 o=!randitem 1,2
 orient=!word $o of fila columna
 orients=!word $o of filas columnas
 inv=!word $o of columna fila
 invs=!word $o of columnas filas
 
 objname=las matrices
 hint=Relación entre las filas y columnas de MN con las de M y N?
 
 parm1=número de $invs of AB\
  Número de $invs de AB \
  AB tiene ?? $invs
 parm2=número de $invs de BC\
  Número de $invs de BC \
  BC tiene ?? $invs
 parm3=número de $invs de CA\
  Número de $invs de CA \
  CA tiene ?? $invs
 t=!shuffle 9
 t=!item $t of 2,3,4,5,6,7,8,9,10
 !distribute item $t into val1,val2,val3
 !distribute item 0,0,0 into weight1,weight2,weight3
 n_=$[$mat%3+1]
 weight$n_=2
 good1=$(val$n_)
 parmcnt=3
 anscnt=1
 minask=1
 !if $o=1
  solution=Como $(matprev)$matname tiene sentido, el número de filas de\
   $matname es igual al número de columnas de $matprev, que a su vez\
   es igual al número de columnas de $matfoll$matprev. <p>\
   Por tanto, $matname tiene $good1 filas.
 !else
  solution=Como $matname$matfoll tiene sentido, el número de columnas de\
   $matname es igual al número de filas de $matfoll, que a su vez\
   es igual al número de filas de $matfoll$matprev. <p>\
   Por tanto, $matname tiene $good1 columnas.
 !endif
!exit

:info
!exit

:final
 !bound ans1 between integer 1 and 20 default ??
 !ifval $ans1=$good1
  thisscore=1
 !endif
!exit

