!! pour simplifier l'écriture d'une équation.

<u><b>Simplificar:</b></u>
!goto $wims_read_parm
!exit

:question
!form reply
   !if $mode=2
      Simplificar la expresión de la ecuación 
      !formselect repexo1 from 1 to 2
      del sistema de ecuaciones.
   !endif
   Cada uno de los miembros de la $nom siguiente :
   !if $mode=2
   <ul>
      <li>Miembro de la izquierda : <input type=text name=repexo2 size=10 value=$repexo2>.</li>
      <li>Miembro de la derecha : <input type=text name=repexo3 size=10 value=$repexo3>.</li>
   </ul>
   !else
     !distribute items $(sys$[$nbetape]) into tmp1,tmp2,tmp3
    <ul>
      <li>\($tmp1=)<input type=text name=repexo2 size=10 value=$repexo2>.</li>
      <li>\($tmp3=)<input type=text name=repexo3 size=10 value=$repexo3>.</li>
   </ul>
   !endif
<input type=hidden name=status value=3>
<center><input type=submit value="Enviar"></center>
</form>
!exit

:reponse
<blockquote>
!if $mode=2
   tmp=!line $repexo1 of $(sys$[$nbetape])
   !distribute items $tmp into tmp1,tmp2,tmp3
   Simplificada la expresión de la ecuación $(repexo1) del sistema de ecuaciones. 
!else
   !distribute items $(sys$[$nbetape]) into tmp1,tmp2,tmp3
!endif
Cada uno de los dos miembros de la $nom siguiente :
<ul>
   !let tmp1=!texmath $tmp1=$repexo2
   !let tmp3=!texmath $tmp3=$repexo3
   <li>\($tmp1)</li>
   <li>\($tmp3)</li>
</ul>
<font color=red><p>ha cometido un error de cálculo.</p></font>
   <p>vous pouvez:</p>
   <ul>
   <li>
   !href cmd=resume&status=2 elegir
   otra simplificación.
   </li>
      <li>
   !href cmd=resume&status=1 regresar
   al menú general.
   </li>
   </ul>
   </blockquote>
!let wims_module_error=error : $erreur
!let erreur=$empty
!exit

:analyse
!! --------------- test si tous les champs sont remplis
!if $repexo2=$empty or $repexo3=$empty or ($repexo1=$empty and $mode=2)
   erreur=$meserreur
   status=2
   !exit
!endif
!! -------------- test de la validité de l'expression donnée.
i=0
replygood0=tt
!for j=2 to 3
   test=$empty
   reply0=$(repexo$[$j])
   !read anstype/algexp
   !if NaN isin $test
      !break
   !endif
!next j
!if NaN isin $test  
   erreur=$meserreur
   status=2
   !exit
!endif

comment$[$nbetape+1]=Simplificación de las expresiones.

!! ------------- Vérification des égalités.
!if $mode!=2
   repexo1=1
!endif
tmp=!line $repexo1 of $(sys$[$nbetape])
!distribute items $tmp into tmp1,tmp2,tmp3
repexo2=!rawmath $repexo2
repexo3=!rawmath $repexo3
tmp=!exec pari $tmp1-($repexo2)\
$tmp3-($repexo3)
tmp=!lines2items $tmp
tmp=!listuniq $tmp
!if $tmp!=0
   !increase nbreerrcalc
   !exit
!endif

!! ------------- calcul de la nouvelle equation/inequation
tmp=$repexo2,$tmp2,$repexo3
!if $mode=2
   sys$[$nbetape+1]=!replace line number $repexo1 by $tmp in $(sys$[$nbetape])
!else
val41=$tmp
   sys$[$nbetape+1]=$tmp
!endif 
!increase nbetape
status=1
evitecalc=0
!exit
