!header
<p>
!if $compute=yes
 !if $error_test!=$empty
  !read msg.phtml
  !goto menu
 !endif
 Resultados de los cálculos solicitados. <p>
 !warn rawmath
 !for i = 1 to $objcnt
  F<sub>$i</sub> = 
  !htmlmath $(xpari$i)
  !if $getfactor=yes
   = $(xfac$i)
  !endif
  <br>
 !next i
 
 !if $gcdlcm=yes
  <br>m.c.d.($Fs) =
  !htmlmath $gcd
  !if $getfactor=yes
   = $gcdfac
  !endif
  <br>m.c.m.($Fs) =
  !htmlmath $lcm
  !if $getfactor=yes
   = $lcmfac
  !endif
 !endif
 
 !if $bezout=yes
  <p> Relación de Bezout:
  !htmlmath $bezres
 !endif
 
 !if $eucdiv=yes
  !let opbeg=<font color=green>
  !let opend=</font>
  !let hdstyle=<small><font color=red>
  !if $euclevel<1
   <p>La división euclídea de F<sub>$euc1</sub> por F<sub>$euc2</sub>
   no ha podido hacerse. ¿Un error de escritura?
   <p>
  !else
   <p>Divisiones euclídeas sucesivas de F<sub>$euc1</sub> por
   F<sub>$euc2</sub>:<p>
   <center><table border=0 cellspacing=3>
   <tr><td align=right>$hdstyle dividendo
   <td><td align=right>$hdstyle cociente
   <td><td align=left>$hdstyle divisor<td>
   <td align=left>$hdstyle resto
   !for i=1 to $euclevel
    <tr><td align=right>
    !htmlmath $(euc1_$i)
    <td> $opbeg=$opend <td align=right>
    !htmlmath $(euc4_$i)
    <td>$opbeg&times;$opend<td align=left>
    !htmlmath $(euc2_$i)
    <td> $opbeg+$opend <td>
    !htmlmath $(euc3_$i)
   !next i
   </table></center>
  !endif euclevel<1?
 !endif

!else
 Esta página calcula las siguientes relaciones aritméticas entre $objcnt 
 enteros o polinomios: m.c.d., m.c.m., división euclídea, relación de Bezout.
!endif compute=yes?

:menu
<p><hr>
!form reply
Puedes introducir tus expresiones (enteros o polinomios de una variable):
<small>(¿Cómo excribir las expresiones? 
!href cmd=help Ejemplos
)</small>
<p>
!for i = 1 to $objcnt
 F<sub>$i</sub> = <input size=50 name=x$i value="$(x$i)"> <br>
!next i
<p>Entonces elije lo que quieres calcular.<ul>
 <li><input type=checkbox name=gcdlcm value=yes
 !if $gcdlcm=yes
  checked
 !endif
 > m.c.d.($Fs) y m.c.c. ($Fs).
 <li><input type=checkbox name=getfactor value=yes
 !if $getfactor=yes
  checked
 !endif
 > Factorización de los enteros y polinomios. (La herramienta
 !href module=tool/algebra/factor.$lang Factoris
 está mejor adaptada para la factorización de un entero simple o un polinomio.)
 <li><input type=checkbox name=bezout value=yes
 !if $bezout=yes
  checked
 !endif
 > Relación de Bezout entre $Fs.
 <li><input type=checkbox name=eucdiv value=yes
 !if $eucdiv=yes
  checked
 !endif
 > Sucesivas divisiones euclídeas de
 <select name=euc1>
 !for i = 1 to $objcnt
  <option value=$i
  !if $i=$euc1
   selected
  !endif
  >F$i
 !next i
 </select> por
 <select name=euc2>
 !for i = 1 to $objcnt
  <option value=$i
  !if $i=$euc2
   selected
  !endif
  >F$i
 !next i
 </select>.
</ul>

<center><input type=submit value="Calcular"></center>
</form>

Puedes cambiar el número de expresiones involucradas:
!for i = 2 to 9
 !if $i != $objcnt
  !href cmd=resume&objcnt=$i&getfactor=$getfactor&bezout=$bezout&eucdiv=$eucdiv&gcdlcm=$gcdlcm&noshow=yes $i
  .
 !endif
!next i

<p>Glosario:
!pedia greatest common divisor, máximo común divisor
,
!pedia least common multiple,mínimo común múltiplo
,
!pedia factorization, factorización
,
!pedia Bezout numbers,relación de Bezout
,
!pedia euclidean algorithm,divisón euclídea
.

:end
<p>
!tail

!for n in getfactor,bezout,eucdiv,gcdlcm,noshow
 !set $n=
!next n

