
<p>

!if $calc=check
 <center><H3> Verificación de número primo </H3></center> <p>
 !if $primarity=yes
  Sí, $check es efectivamente un número primo.
 !endif
 !if $primarity=no
  No, $check es un número compuesto!
 !endif
 !if $primarity=?
  La verificación de número primo de $check ha fallado. Lo sentimos.
 !endif
 <p>
 !href cmd=reply&calc=resume Regresar al resultado de la búsqueda
 !goto end
!endif

!if $method=all
 Primos comenzando desde $all : <p>
 !for i in $primes
  !set checking=$i
  !read primecheck.phtml
  &nbsp;
 !next i
 !if $wims_mode=popup
  !exit
 !endif
 <p>
 !if $all_dir=down
  !href cmd=reply&calc=yes&all=$i-1 Continuación de la lista
 !else
  !href cmd=reply&calc=yes&all=$i+1 Continuación de la lista
 !endif
 !goto end
!endif

!if $method=rand
 !if $rand1!=next and $rand1!=prec
  Un número primo aleatorio de $rand cifras:
 !else
  Continuación empezando desde un número primo aleatorio de $rand cifras:
 !endif
 <p><center>
 !set checking=$primes
 !read primecheck.phtml
 </center> <p>
 !if $rand_warn != $empty
  <b>Nota.</b> El número de cifras está limitado entre $rand_min y $rand_max.
 !endif
 !if $wims_mode=popup
  !exit
 !endif
 Puede ver el número primo
 !href cmd=reply&rand1=prec&calc=yes precedente
 o
 !href cmd=reply&rand1=next&calc=yes siguiente
 a éste
 !goto end
!endif

!if $method=lin
 Números primos en progresión aritmética
 !htmlmath ($a) n + ($b)
 , comenzando desde $m_n = $n : <p>
 <center><table border=0 cellpadding=0 cellspacing=0>
 !for i in $primes
  !set i1=!word 1 of $i
  !set i2=!word 2 of $i
  <tr><td> $m_n&nbsp;= <td align=right>$i1,&nbsp;
  <td>$m_p&nbsp;= <td align=right>
  !set checking=$i2
  !read primecheck.phtml
 !next i
 </table></center> <p>
 !if $wims_mode=popup
  !exit
 !endif
 !if $lin_dir=down
  !href cmd=reply&calc=yes&n=$i1-1 Continuación de la lista
 !else
  !href cmd=reply&calc=yes&n=$i1+1 Continuación de la lista
 !endif
 !goto end
!endif

:end
, o
!href cmd=resume regresar al menú
 para otra búsqueda.

!if $probable=yes
 <p><hr width=25%> <p><font color=red><b>Atención.</b></font>
 Los números que aparezcan en azul son únicamente
 !href cmd=help&help_subject=certified probables primos
. Puede hacer click en ellos para verificar rigurosamente si son primos.
 !if $bigprobable=yes
  <p>Nótese que para probar si un número de más de 45 cifras es primo,
  éste será enviado al programa ECPP de François Morain, disponible 
  en línea en
  <a href="http://www.fsp.com" target=wims_external>Freelance Systems Programming</a>. La 
  computación será mostrada en una nueva ventana de su navegador; la última
  línea del script le dirá si el número es primo.
  <p>
  <font color=red><b>Advertencia.</b></font>
  Es altamente desaconsejable utilizar esta herramienta para usos de encriptación en situaciones
  reales. Los números primos viajando a través de la red no tienen ninguna confidenciabilidad y pueden ser
  leidos por otros usuarios de la misma.
 !endif
 <p><hr width=25%>
!endif

!set calc=

<p>

