!set title=Solución nula

!goto $wims_read_parm

:present
Sea el sistema de ecuaciones lineales con coeficientes reales
<p><center><table border=0>
 <tr><td rowspan=4>$m_leftbrace4
 <td align=center>a<sub>11</sub>x<sub>1</sub> +
  a<sub>12</sub>x<sub>2</sub> + ... + a<sub>1n</sub>x<sub>n</sub> =
  b<sub>1</sub>
 <tr><td align=center>a<sub>21</sub>x<sub>1</sub> +
  a<sub>22</sub>x<sub>2</sub> + ... + a<sub>2n</sub>x<sub>n</sub> =
  b<sub>2</sub>
 <tr><td align=center>...
 <tr><td align=center>a<sub>m1</sub>x<sub>1</sub> +
  a<sub>m2</sub>x<sub>2</sub> + ... + a<sub>mn</sub>x<sub>n</sub> =
  b<sub>m</sub>
 </table></center>
<p>La tarea consiste en saber cuándo
(x<sub>1</sub>,x<sub>2</sub>,...,x<sub>n</sub>) = (0,0,...,0)
es una solución de este sistema.
!exit

:form
 (0,0,...,0)
 !formselect ans1 list ??,1,2 prompt ????,es,no es
 una solución del sistema.
!exit

:ans
 Tu respuesta ha sido que (0,0,...,0) 
 !item $ans1 of es, no es
 una solución.
 !ifval $ans1=$good1
  <font color=green>Correcto</font>.
 !else
  <font color=red>Respuesta errónea</font>: de hecho, 
 !item $good1 of es, no es
 una solución.
 !endif
!exit

:init
objname=este sistema lineal
hint=

parm1=number of variables\
 Número de incógnitas del sistema\
 El sistema tiene n = ?? incógnitas
val1=!randint 5,15
weight1=0
parm2=number of equations\
 Número de ecuaciones del sistema\
 elsistema tiene m = ?? ecuaciones
val2=!randint $val1,$val1+2
weight2=0
parm3=number of independent equations\
 Número de ecuaciones independientes en el sistema\
 el sistema tiene m = ?? ecuaciones independientes
val3=!randint $val1,$val1+2
weight3=0
parm4=homogeneousness\
 Es un sistema homogéneo\
 El sistema es ??
weight4=2
parm5=sum of coefficients\
 Suma de los coeficientes = \
 La suma de los coeficientes es igual a ??
val5=!randint -20,20
weight5=0
parm6=sum of constant terms\
 Suma de los términos b<sub>i</sub> = \
 La suma de los términos $m_sum<sub>i</sub>b<sub>i</sub> = ??
weight6=1

parmcnt=6
anscnt=1
minask=1

!if random(100)<50
 val4=homogeneous
 val6=0
 good1=1
!else
 val4=non-homogeneous
 val6=!randint -20,20
 good1=2
!endif
!exit

:info
!exit

:final
 !bound ans1 within 1,2 default ??
 !ifval $ans1=$good1
  thisscore=1
 !endif
 !if 6 isitemof $gotlist and $val6!=0
  weight4=1
 !endif
!exit

