!header

!if $cmd=hint
  !if $special_parm != heavy
    !changeto hint.phtml
  !else
    !changeto hint2.phtml
  !endif  
!endif  

<center>
!insplot [-$x_range:$x_range] \
($oc0)+($oc1)*x+($oc2)*x^2+($oc3)*x^3+($oc4)*x^4+($oc5)*x^5+$reste_fn\
title "f(x)", \
($c0) +($c1) *x+($c2) *x^2+($c3) *x^3+($c4) *x^4+($c5)*x^5 title "Mi desarrollo"
</center>

!if $write_solution=yes
  Es una lásitima que haya abandonado. La solución es:<p><center>
  f(x) = $poly_html + o(x<sup>$Degree</sup>)
  </center> <p>
  !goto end_abandon
!endif

!if $[$diff] = 0 and $poly_html != $empty
 ¡Bravo! Ha encontrado el desarrollo adecuado después de $reply_cnt intentos:
 <p><center>
 f(x) = $poly_html + o(x<sup>$Degree</sup>)
 </center> <p>
 Su puntuación: $module_score/10. <p>
 !goto end_form
!endif $diff=0

!ifval $reply_cnt = 0
  Aquí tiene la curva de una función f(x). Debe hallar su
!else
  Busque el
!endif
desarrollo de Taylor
<p><center>
f(x) = 
!word 1 to 1+2*$Degree of\
  c<sub>0</sub> + c<sub>1</sub>x + c<sub>2</sub>x<sup>2</sup>\
  + c<sub>3</sub>x<sup>3</sup> + c<sub>4</sub>x<sup>4</sup>\
  + c<sub>5</sub>x<sup>5</sup>
+ o(x<sup>$Degree</sup>)
,
</center> <p>
donde los coeficientes

!word 1 to 1+$Degree of\
 c<sub>0</sub>, c<sub>1</sub>, c<sub>2</sub>, c<sub>3</sub>, c<sub>4</sub>, c<sub>5</sub>

son números enteros comprendidos entre -$range y $range (inclusive).
<hr>Intento número $try_cnt:

!form reply
!for i = 0 to $Degree
  c<sub>$i</sub>=<input name=c$i value=$(c$i) size=3>
!next i  
<input type=submit value="Enviar la respuesta">
</form>
:end_form
<hr>

!ifval $diff != 0
  !href cmd=hint Consejos
  .
  !href cmd=reply&abandon=yes Abandono; enséñeme la solución
  .
!endif

:end_abandon
!href cmd=renew&worksheet=$wims_sheet&$module_init_parm Otra función
 .

!form config
<input type=submit value="Preferencias.">
Zoom:

!for i = -2 to 2
  <input type=radio name=zoom_factor value=$i
  !ifval $zoom_factor = $i
    checked
  !endif
  > 
  !word $i+3 of 12.5mm 25mm 50mm 100mm 200mm
  &nbsp;&nbsp;
!next i
<br>
Tamaño del dibujo:
!for i = -1 to 1
  <input type=radio name=size_factor value=$i
  !ifval $size_factor = $i
    checked
  !endif
  >
  !word $i+2 of pequeño mediano grande
  &nbsp;&nbsp;
!next i  
</form>
!tail

