Data_Dumper

# NAME

Dumper - stringified perl data structures, suitable for both printing and eval

# SYNOPSIS

        use Data::Dumper;
        # simple procedural interface
        print Dumper($foo, $bar);
        # extended usage with names
        print Data::Dumper->Dump([$foo, $bar], [qw(foo *ary)]);
        # configuration variables
        {
          local $Data::Dump::Purity = 1;
          eval Data::Dumper->Dump([$foo, $bar], [qw(foo *ary)]);
        }
        # OO usage
        $d = Data::Dumper->new([$foo, $bar], [qw(foo *ary)]);
           ...
        print $d->Dump;
           ...
        $d->Purity(1);
        eval $d->Dump;

# DESCRIPTION

Given a list of scalars or reference variables, writes out their contents in perl syntax. The references can also be objects. The contents of each variable is output in a single Perl statement.

The return value can be eval ed to get back the original reference structure. Bear in mind that a reference so created will not preserve pointer equalities with the original reference.

Handles self-referential structures correctly. Any references that are the same as one of those passed in will be marked `$VARI$VARIThe default output of self-referential structures can be eval ed, but the nested references to `$VARI $Data::Dumper::Purity to 1 to get additional statements that will correctly fill in these references.``

In the extended usage form, the supplied references can be given user-specified names. If a supplied name begins with a `*`, the output will describe the dereferenced type of the supplied reference for hashes and arrays.

Several styles of output are possible, all controlled by setting $Data::Dumper::Indent or using the corresponding method name. Style 0 spews output without any newlines, indentation, or spaces between list items. It is the most compact format possible that can still be called valid perl. Style 1 outputs a readable form with newlines but no fancy indentation (each level in the structure is simply indented by a fixed amount of whitespace). Style 2 (the default) outputs a very readable form which takes into account the length of hash keys (so the hash value lines up). Style 3 is like style 2, but also annotates the elements of arrays with their index (but the comment is on its own line, so array output consumes twice the number of lines).

## Methods

PACKAGE->new(ARRAYREF [, ARRAYREF])
  Returns a newly created Dumper object. The first argument is an anonymous array of values to be dumped. The optional second argument is an anonymous array of names for the values. The names need not have a leading `$` sign, and must be comprised of alphanumeric characters. You can begin a name with a `*` to specify that the dereferenced type must be dumped instead of the reference itself.

  The prefix specified by $Data::Dumper::Varname will be used with a numeric suffix if the name for a value is undefined.

$< EM>OBJ->Dump or PACKAGE->Dump(ARRAYREF [, ARRAYREF])
  Returns the stringified form of the values stored in the object (preserving the order in which they were supplied to `new`), subject to the configuration options below.

  The second form, for convenience, simply calls the `new` method on its arguments before dumping the object immediately.

$< EM>OBJ->Seen([HASHREF])
  Queries or adds to the internal table of already encountered references. You must use `Reset` to explicitly clear the table if needed. Such references are not dumped; instead, their names are inserted wherever they are to be dumped subsequently.

  Expects a anonymous hash of name => value pairs. Same rules apply for names as in `new`. If no argument is supplied, will return the ``seen'' list of name => value pairs, in an array context.

$< EM>OBJ->Values([ARRAYREF])
  Queries or replaces the internal array of values that will be dumped.

$< EM>OBJ->Names([ARRAYREF])
  Queries or replaces the internal array of user supplied names for the values that will be dumped.

$< EM>OBJ->Reset
  Clears the internal table of ``seen'' references.

## Functions

Dumper(LIST)
  Returns the stringified form of the values in the list, subject to the configuration options below. The values will be named `$VARII`

## Configuration Variables/Methods

Several configuration variables can be used to control the kind of output generated when using the procedural interface. These variables are usually local ized in a block so that other parts of the code are not affected by the change.

These variables determine the default state of the object created by calling the `new` method, but cannot be used to alter the state of the object thereafter. The equivalent method names should be used instead to query or set the internal state of the object.

$Data::Dumper::Indent or $< EM>OBJ->Indent([NEWVAL])
  Controls the style of indentation. It can be set to 0, 1, 2 or 3. 2 is the default.

$Data::Dumper::Purity or $< EM>OBJ->Purity([NEWVAL])
  Controls the degree to which the output can be eval ed to recreate the supplied reference structures. Setting it to 1 will output additional perl statements that will correctly recreate nested references. The default is 0.

$Data::Dumper::Pad or $< EM>OBJ->Pad([NEWVAL])
  Specifies the string that will be prefixed to every line of the output. Empty string by default.

$Data::Dumper::Varname or $< EM>OBJ->Varname([NEWVAL])
  Contains the prefix to use for tagging variable names in the output. The default is ``VAR''.

## Exports

Dumper

  # EXAMPLE

          use Data::Dumper;
          package Foo;
          sub new {bless {'a' => 1, 'b' => sub { return "foo" }}, $_[0]};
          package Fuz;                       # a wierd REF-REF-SCALAR object
          sub new {bless \($_ = \ 'fu\'z'), $_[0]};
          package main;
          $foo = Foo->new;
          $fuz = Fuz->new;
          $boo = [ 1, [], "abcd", \*foo,
                   {1 => 'a', 023 => 'b', 0x45 => 'c'},
                   \\"p\q\'r", $foo, $fuz];
          $bar = eval(Dumper($boo));
          print($@) if $@;
          print Dumper($boo), Dumper($bar);  # pretty print (no array indices)

          $Data::Dumper::Indent = 0;         # turn off all pretty print
          print Dumper($boo), "\n";
          $Data::Dumper::Indent = 1;         # mild pretty print
          print Dumper($boo);
          $Data::Dumper::Indent = 3;         # pretty print with array indices
          print Dumper($boo);
          # recursive structure
          @c = ('c');
          $c = \@c;
          $b = {};
          $a = [1, $b, $c];
          $b->{a} = $a;
          $b->{b} = $a->[1];
          $b->{c} = $a->[2];
          print Data::Dumper->Dump([$a,$b,$c], [qw(a b c)]);
          $Data::Dumper::Purity = 1;         # fill in the holes for eval
          print Data::Dumper->Dump([$a, $b], [qw(*a b)]); # print as @a
          print Data::Dumper->Dump([$b, $a], [qw(*b a)]); # print as %b
          $d = Data::Dumper->new([$a,$b], [qw(a b)]);     # go OO
          $d->Seen({'*c' => $c});            # stash a ref without printing it
          $d->Indent(3);
          print $d->Dump;
          $d->Reset;                         # empty the seen cache
          $d->Purity(0);
          print $d->Dump;

  # BUGS

  Due to limitations of Perl subroutine call semantics, you can't pass an array or hash. Prepend it with a `\` to pass its reference instead. This will be remedied in time, with the arrival of prototypes in later versions of Perl. For now, you need to use the extended usage form, and prepend the name with a `*` to output it as a hash or array.

  Dumper cheats with CODE references. If a code reference is encountered in the structure being processed, an anonymous subroutine returning the perl string-interpolated representation of the original CODE reference will be inserted in its place, and a warning will be printed if `Purity` is set. You can eval the result, but bear in mind that the anonymous sub that gets created is a dummy placeholder. Someday, perl will have a switch to cache-on-demand the string representation of a compiled piece of code, I hope.

  SCALAR objects have the wierdest looking bless workaround.

  # AUTHOR

  Gurusamy Sarathy gsar@umich.edu

  Copyright (c) 1995 Gurusamy Sarathy. All rights reserved. This program is free software; you can redistribute it and/or modify it under the same terms as Perl itself.

  # VERSION

  Version 1.23 3 Dec 1995

  # SEE ALSO

  perl(1)