#!perl

our $DATE = '2015-09-03'; # DATE
our $VERSION = '0.02'; # VERSION

use 5.010;
use strict;
use warnings;

use Perinci::CmdLine::Any;

our %SPEC;

$SPEC{prog} = {
    v => 1.1,
    summary => 'Generate bash completion script for a program',
    args => {
        overwrite => {
            schema => 'bool*',
        },
        input => {
            schema => 'str*',
            req    => 1,
            pos    => 0,
            cmdline_aliases => {i=>{}},
        },
        output => {
            schema => 'str*',
            pos    => 1,
            cmdline_aliases => {o=>{}},
        },
    },
};
sub prog {
    require App::GenBashCompleter;
    my %args = @_;

    my $input  = $args{input};
    my $output = $args{output};
    if (!defined($output)) {
        if ($input eq '-') {
            $output = '-';
        } else {
            $output = $input;
            $output =~ s!(.+[/\\])?(.+)!($1 // '') . "_$2"!e;
        }
    }

    my $res = App::GenBashCompleter::gen_bash_completer(path=>$input);

    return $res if $res->[0] != 200;
    return [304, "Can't figure out how to create bash completion script for " .
                "'$input': " . $res->[3]{'func.reason'}]
        if !defined($res->[2]);
    return $res if $output eq '-';

    # write output file
    if ((-e $output) && !$args{overwrite}) {
        return [409, "File already exists: '$output', bailing"];
    }
    open my($fh), ">", $output
        or return [500, "Can't write to '$output': $!"];
    print $fh $res->[2];
    chmod 0755, $output;

    [200, "OK (written to file '$output')"];
}

Perinci::CmdLine::Any->new(
    url => '/main/prog',
    log => 1,
)->run;

# ABSTRACT: Generate bash completion script for a program
# PODNAME: gen-bash-completer

__END__

=pod

=encoding UTF-8

=head1 NAME

gen-bash-completer - Generate bash completion script for a program

=head1 VERSION

This document describes version 0.02 of gen-bash-completer (from Perl distribution App-GenBashCompleter), released on 2015-09-03.

=head1 SYNOPSIS

 % gen-bash-completer foo

If successful will produce C<_foo>, which you can use for bash completion:

 % complete -C _foo foo

Now you can use tab completion to complete C<foo>:

 % foo <tab>
 % foo --op<tab>

and so on.

=head1 DESCRIPTION

C<gen-bash-completer> accepts a program/script file and uses various ways to try
to generate bash completion script which you can later you in bash's C<complete
-C> to provide completion.

Currently the kinds of script it recognizes are:

=over

=item * Perl script which uses Getopt::Long::Complete or Perinci::CmdLine

This is script that can complete itself, because the said modules can handle
bash completion for it. For these scripts, C<gen-bash-completer> will just do
nothing.

=item * Perl script which uses Getopt::Long

For this kind of script, C<gen-bash-completer> will load L<Getopt::Long>,
temporarily patch/trap the C<GetOptions> function (as well as
C<GetOptionsFromArray> and C<GetOptionsFromString>), and run the Perl script.
The patched function will simply capture the options specification and exit. We
then feed this specification to L<Getopt::Long::Complete>.

=item * Others

Other methods will be added in the future, e.g. reading C<OPTIONS> section in a
Perl script's POD, support for other command-line option parsing modules, etc.

=back

=head1 OPTIONS

C<*> marks required options.

=head2 Configuration options

=over

=item B<--config-path>=I<filename>

Set path to configuration file.

Can be specified multiple times.

=item B<--config-profile>=I<s>

Set configuration profile to use.

=item B<--no-config>

Do not use any configuration file.

=back

=head2 Environment options

=over

=item B<--no-env>

Do not read environment for default options.

=back

=head2 Logging options

=over

=item B<--debug>

Set log level to debug (note: you also need to set LOG=1 to enable logging, or use DEBUG=1).

=item B<--log-level>=I<s>

Set log level (note: you also need to set LOG=1 to enable logging).

=item B<--quiet>

Set log level to quiet (note: you also need to set LOG=1 to enable logging, or use QUIET=1).

=item B<--trace>

Set log level to trace (note: you also need to set LOG=1 to enable logging, or use TRACE=1).

=item B<--verbose>

Set log level to info (note: you also need to set LOG=1 to enable logging, or use VERBOSE=1).

=back

=head2 Output options

=over

=item B<--format>=I<s>

Choose output format, e.g. json, text.

Default value:

 undef

=item B<--json>

Set output format to json.

=item B<--naked-res>

When outputing as JSON, strip result envelope.

Default value:

 0

By default, when outputing as JSON, the full enveloped result is returned, e.g.:

    [200,"OK",[1,2,3],{"func.extra"=>4}]

The reason is so you can get the status (1st element), status message (2nd
element) as well as result metadata/extra result (4th element) instead of just
the result (3rd element). However, sometimes you want just the result, e.g. when
you want to pipe the result for more post-processing. In this case you can use
`--naked-res` so you just get:

    [1,2,3]


=back

=head2 Other options

=over

=item B<--help>, B<-h>, B<-?>

Display help message and exit.

=item B<--input>=I<s>*, B<-i>

=item B<--output>=I<s>, B<-o>

=item B<--overwrite>

=item B<--version>, B<-v>

Display program's version and exit.

=back

=head1 SEE ALSO

L<Dist::Zilla::Plugin::GenBashCompleter>

=head1 COMPLETION

This script has shell tab completion capability with support for several
shells.

=head2 bash

To activate bash completion for this script, put:

 complete -C gen-bash-completer gen-bash-completer

in your bash startup (e.g. C<~/.bashrc>). Your next shell session will then
recognize tab completion for the command. Or, you can also directly execute the
line above in your shell to activate immediately.

It is recommended, however, that you install L<shcompgen> which allows you to
activate completion scripts for several kinds of scripts on multiple shells.
Some CPAN distributions (those that are built with
L<Dist::Zilla::Plugin::GenShellCompletion>) will even automatically enable shell
completion for their included scripts (using C<shcompgen>) at installation time,
so you can immadiately have tab completion.

=head2 tcsh

To activate tcsh completion for this script, put:

 complete gen-bash-completer 'p/*/`gen-bash-completer`/'

in your tcsh startup (e.g. C<~/.tcshrc>). Your next shell session will then
recognize tab completion for the command. Or, you can also directly execute the
line above in your shell to activate immediately.

It is also recommended to install C<shcompgen> (see above).

=head2 other shells

For fish and zsh, install C<shcompgen> as described above.

=head1 ENVIRONMENT

=head2 GEN_BASH_COMPLETER_OPT => str

Specify additional command-line options

=head1 CONFIGURATION FILE

This script can read configuration file, which by default is searched at C<~/.config/gen-bash-completer.conf>, C<~/gen-bash-completer.conf> or C</etc/gen-bash-completer.conf> (can be changed by specifying C<--config-path>). All found files will be read and merged.

To disable searching for configuration files, pass C<--no-config>.

Configuration file is in the format of L<IOD>, which is basically INI with some extra features. 

You can put multiple profiles in a single file by using section names like C<[profile=SOMENAME]>. Those sections will only be read if you specify the matching C<--config-profile SOMENAME>.

List of available configuration parameters:

 format (see --format)
 input (see --input)
 log_level (see --log-level)
 naked_res (see --naked-res)
 output (see --output)
 overwrite (see --overwrite)

=head1 FILES

~/.config/gen-bash-completer.conf

~/gen-bash-completer.conf

/etc/gen-bash-completer.conf

=head1 HOMEPAGE

Please visit the project's homepage at L<https://metacpan.org/release/App-GenBashCompleter>.

=head1 SOURCE

Source repository is at L<https://github.com/perlancar/perl-App-GenBashCompleter>.

=head1 BUGS

Please report any bugs or feature requests on the bugtracker website L<https://rt.cpan.org/Public/Dist/Display.html?Name=App-GenBashCompleter>

When submitting a bug or request, please include a test-file or a
patch to an existing test-file that illustrates the bug or desired
feature.

=head1 AUTHOR

perlancar <perlancar@cpan.org>

=head1 COPYRIGHT AND LICENSE

This software is copyright (c) 2015 by perlancar@cpan.org.

This is free software; you can redistribute it and/or modify it under
the same terms as the Perl 5 programming language system itself.

=cut
