        SUBROUTINE  MDM
     *     (VK,TAIL, V,L, LAST,NEXT, MARK)                                OD 371
        INTEGER  VK, TAIL,  V(1), L(1),   LAST(1), NEXT(1),   MARK(1),    OD 372
     *     TAG, S,LS,VS,ES, B,LB,VB, BLP,BLPMAX                           OD 373
        EQUIVALENCE  (VS, ES)                                             OD 374
C                                                                         OD 375
C----INITIALIZE TAG AND LIST OF UNELIMINATED NEIGHBORS                    OD 376
        TAG = MARK(VK)                                                    OD 377
        TAIL = VK                                                         OD 378
C                                                                         OD 379
C----FOR EACH VERTEX/ELEMENT VS/ES IN ELEMENT LIST OF VK                  OD 380
        LS = L(VK)                                                        OD 381
   1    S = LS                                                            OD 382
        IF (S.EQ.0)  GO TO 5                                              OD 383
          LS = L(S)                                                       OD 384
          VS = V(S)                                                       OD 385
          IF (NEXT(VS).LT.0)  GO TO 2                                     OD 386
C                                                                         OD 387
C------IF VS IS UNELIMINATED VERTEX, THEN TAG AND APPEND TO LIST OF       OD 388
C------UNELIMINATED NEIGHBORS                                             OD 389
            MARK(VS) = TAG                                                OD 390
            L(TAIL) = S                                                   OD 391
            TAIL = S                                                      OD 392
            GO TO 4                                                       OD 393
C                                                                         OD 394
C------IF ES IS ACTIVE ELEMENT, THEN ...                                  OD 395
C--------FOR EACH VERTEX VB IN BOUNDARY LIST OF ELEMENT ES                OD 396
   2        LB = L(ES)                                                    OD 397
            BLPMAX = LAST(ES)                                             OD 398
            DO 3 BLP=1,BLPMAX                                             OD 399
              B = LB                                                      OD 400
              LB = L(B)                                                   OD 401
              VB = V(B)                                                   OD 402
C                                                                         OD 403
C----------IF VB IS UNTAGGED VERTEX, THEN TAG AND APPEND TO LIST OF       OD 404
C----------UNELIMINATED NEIGHBORS                                         OD 405
              IF (MARK(VB).GE.TAG)  GO TO 3                               OD 406
                MARK(VB) = TAG                                            OD 407
                L(TAIL) = B                                               OD 408
                TAIL = B                                                  OD 409
   3          CONTINUE                                                    OD 410
C                                                                         OD 411
C--------MARK ES INACTIVE                                                 OD 412
            MARK(ES) = TAG                                                OD 413
C                                                                         OD 414
   4      GO TO 1                                                         OD 415
C                                                                         OD 416
C----TERMINATE LIST OF UNELIMINATED NEIGHBORS                             OD 417
   5    L(TAIL) = 0                                                       OD 418
C                                                                         OD 419
        RETURN                                                            OD 420
        END                                                               OD 421
