#!perl

use 5.010;
use strict;
use warnings;

use App::PMUtils;
use Perinci::CmdLine::Lite;

our $DATE = '2014-07-29'; # DATE
our $VERSION = '0.19'; # VERSION

our %SPEC;
$SPEC{pmedit} = {
    v => 1.1,
    summary => 'Launch editor for Perl module source code',
    args => {
        module => {
            schema => 'str*',
            req => 1,
            pos => 0,
            completion => $App::PMUtils::_complete_module,
        },
    },
};
sub pmedit {
    require SHARYANTO::Module::Path;
    require String::ShellQuote;

    my %args = @_;
    my $mod = $args{module};
    my $mpath = SHARYANTO::Module::Path::module_path(
        module => $mod, find_pmc=>0, find_pod=>0, find_prefix=>0);
    return [412, "Please set EDITOR first"] unless defined($ENV{EDITOR});
    return [500, "Can't find path for $mod"] unless defined $mpath;

    # array variant doesn't always work because $EDITOR can contain args, e.g.
    # "emacsclient -t".
    my $cmd = "$ENV{EDITOR} ".String::ShellQuote::shell_quote($mpath);
    exec $cmd;
    # [200]; # unreached
}

Perinci::CmdLine::Lite->new(
    url => '/main/pmedit',
)->run;

# ABSTRACT: Launch editor for Perl module source code
# PODNAME: pmedit

__END__

=pod

=encoding UTF-8

=head1 NAME

pmedit - Launch editor for Perl module source code

=head1 VERSION

This document describes version 0.19 of pmedit (from Perl distribution App-PMUtils), released on 2014-07-29.

=head1 SYNOPSIS

Basic usage:

 % pmedit Some::Module

To active bash completion:

 % complete -C pmedit pmedit ; # can be put in bash startup file e.g. .bashrc
 % pmedit Some<tab>
 % pmedit test/builder/mo<tab> ; # resolve to Test/Builder/Module, can resolve case
 % pmedit "Text::Abb<tab>      ; # use quote (' or ") if you want to use :: as separator

=head1 HOMEPAGE

Please visit the project's homepage at L<https://metacpan.org/release/App-PMUtils>.

=head1 SOURCE

Source repository is at L<https://github.com/sharyanto/perl-App-PMUtils>.

=head1 BUGS

Please report any bugs or feature requests on the bugtracker website L<https://rt.cpan.org/Public/Dist/Display.html?Name=App-PMUtils>

When submitting a bug or request, please include a test-file or a
patch to an existing test-file that illustrates the bug or desired
feature.

=head1 AUTHOR

Steven Haryanto <stevenharyanto@gmail.com>

=head1 COPYRIGHT AND LICENSE

This software is copyright (c) 2014 by Steven Haryanto.

This is free software; you can redistribute it and/or modify it under
the same terms as the Perl 5 programming language system itself.

=cut
