#! /bin/csh -f

    set msg = 'mk-tester:'
    set do_start = TRUE

    while ($#argv != 0)
        if ("$argv[1]"  == '-no_start') then
            set do_start = FALSE
        else if ("$argv[1]"  == '-mfile') then
	    shift argv
	    set mfile = "$argv[1]"
        else if ("$argv[1]"  == '-sb_dir') then
	    shift argv
	    set sb_dir = "$argv[1]"
        endif
        shift argv
    end

    echo "$msg mfile: $mfile sb_dir: $sb_dir"

    set root = $mfile:r
    set hfile = ${root}.h
    set name = $root:t
    set code_dir = $mfile-PlayNote
    if ( -e $code_dir) then
        /bin/rm -rf $code_dir
    endif
    mkdir $code_dir
    cp -p $sb_dir/PlayNote.tar $code_dir
    cd $code_dir
    tar -xf PlayNote.tar
    /bin/rm PlayNote.tar

    cd PlayNote
    cp -p $mfile $hfile .
    set sed_sh = /tmp/sed.$USER.$$
    cat <<EOF >$sed_sh
s/TheUsersSynthPatchName/$name/g
EOF

    set files = (PB.project ExampApp.m Makefile)
    foreach file ($files)
        sed -f $sed_sh <$file >$file.new
        mv $file.new $file
    end

    make

# Delete the obj directory to save some disk space
# Also strip the app.  Finally start it if necessary

    if (-e PlayNote.app/PlayNote) then
        strip PlayNote.app/PlayNote
        /bin/rm -rf obj
        if ($do_start == TRUE) then
            open PlayNote.app &
        endif
    endif
