# File generated by kdevelop's qmake manager. 
# ------------------------------------------- 
# Subdir relative project main directory: .
# Target is an application:  

FORMS += packagesearch.ui \
         packagesearchaboutdlg.ui \
         plugincontrol.ui \
         columncontroldlg.ui \
 settingsdlg.ui
HEADERS += packagesearchimpl.h \
           history.h \
           runcommand.h \
           runcommandinxterm.h \
           extalgorithm.h \
           applicationfactory.h \
           exception.h \
           helpers.h \
           informationplugin.h \
           plugin.h \
           iprovider.h \
           searchplugin.h \
           plugincontainer.h \
           singleton.h \
           shortinformationplugin.h \
           runcommandforoutput.h \
           xmldata.h \
           pluginmanager.h \
           ipluginuser.h \
           settingsdlg.h \
           plugininformer.h \
           baseplugincontainer.h \
           ipluginfactory.h \
           iplugininformer.h \
           packagenotfoundexception.h \
           packagenameplugin.h \
           iprogressobserver.h \
           progressdisplaydlg.h \
           ixmlstorable.h \
           processcontainer.h \
           scoredisplayplugin.h \
           scoreplugin.h \
           plugincompare.h \
           iscorecalculationstrategy.h \
           scorecalculationstrategybase.h \
           columncontroldlg.h \
           action.h \
           actionplugin.h \
           globals.h \
           packagesearchaboutdlg.h \
           packagedisplaywidget.h \
 plugincontroldlgmeditator.h \
 gainroot.h \
 networksettings.h
SOURCES += main.cpp \
           packagesearchimpl.cpp \
           history.cpp \
           runcommandinxterm.cpp \
           extalgorithm.cpp \
           applicationfactory.cpp \
           exception.cpp \
           plugincontainer.cpp \
           plugin.cpp \
           singleton.cpp \
           runcommandforoutput.cpp \
           xmldata.cpp \
           pluginmanager.cpp \
           settingsdlg.cpp \
           plugininformer.cpp \
           baseplugincontainer.cpp \
           packagenotfoundexception.cpp \
           packagenameplugin.cpp \
           progressdisplaydlg.cpp \
           processcontainer.cpp \
           scoredisplayplugin.cpp \
           scorecalculationstrategybase.cpp \
           columncontroldlg.cpp \
           action.cpp \
           actionplugin.cpp \
           packagesearchaboutdlg.cpp \
           packagedisplaywidget.cpp \
 plugincontroldlgmeditator.cpp \
 gainroot.cpp \
 runcommand.cpp \
 networksettings.cpp
# libdl required for dl{open,..}()
LIBS += -ldl
LANGUAGE = C++
TEMPLATE = app
CONFIG += warn_on \
	qt \
	thread \
	stl \
	link_pkgconfig

TRANSLATIONS = ../translations/packagesearch_de.ts \
	../translations/packagesearch_es.ts

UI_DIR = .ui
MOC_DIR = .moc
# libraries used by packagesearch which offer pkg-config
PKGCONFIG += libept libtagcoll2
INCLUDEPATH += ./
QT += xml network
isEmpty(USE_KDE_LIBS){
    message("USE_KDE_LIBS not set, assuming false by default")
    USE_KDE_LIBS = false
}
contains(USE_KDE_LIBS, true){
    message("KDE support enabled")
    INCLUDEPATH += /usr/include/kde
    LIBS += -lkdecore
    DEFINES += __USE_KDE_LIBS
}


debug {
    message("generating debug version")
    OBJECTS_DIR = .obj_debug
    DEFINES += __DEBUG
    CONFIG -= release
}
else {
    message("generating release version")
    OBJECTS_DIR = .obj
}


# creating Makefile for test cases (CONFIG += test)


# build a library from the packagesearch application here, to allow
# plugins to use the library for their test cases
testlib {
    OBJECTS_DIR = .obj_debug
    DEFINES += __DEBUG
	 message("generating test library")
    TEMPLATE = lib
    QMAKE_MAKEFILE = Makefile.testlib
    SOURCES -= main.cpp
    INCLUDEPATH += .moc/ 
    # object files for libraries are build differently from applications
    # thus we require another object dir
    # we do not distinguish between debug and release here
    OBJECTS_DIR = .obj_test
}
# yeah, go for C++11!
# QMAKE_CXXFLAGS += -std=c++0x

# add standard Debian flags
QMAKE_CXXFLAGS_RELEASE += $$system(dpkg-buildflags --get CPPFLAGS)
QMAKE_CXXFLAGS_RELEASE += $$system(dpkg-buildflags --get CXXFLAGS)
QMAKE_LFLAGS += $$system(dpkg-buildflags --get LDFLAGS)

# export-dynamic is required to export all symbols (not only used ones) to symbol tables
# it is required because of the use of dlopen
# -Wl,--no-add-needed prevents the linker from transitively infering library relationships
QMAKE_LFLAGS_THREAD += -Wl,-export-dynamic -Wl,--no-add-needed

# QMAKE_CXX = g++-4.6
