_zimfw_compile() {
  # Compile zimfw scripts
  local zroot_dir zfile
  for zroot_dir in ${_zroot_dirs:|_zdisabled_paths}; do
    if [[ ! -w ${zroot_dir} ]]; then
      _zimfw_print -R "${_zwarn}${_zbold}${zroot_dir}:${_znormalyellow} No write permission, unable to compile.${_znormal}"
      continue
    fi
    for zfile in ${zroot_dir}/(^*test*/)#*.zsh(|-theme)(N-.); do
      if [[ ! ${zfile}.zwc -nt ${zfile} ]]; then
        zcompile -R ${zfile} && _zimfw_print -R "${_zokay}${_zbold}${zfile}.zwc:${_znormal} Compiled"
      fi
    done
  done
  _zimfw_print 'Done with compile.'
}
