!read adm/css.phtml
!if $(module_title_$moduclass_lang)!=$empty
  !set module_title=$(module_title_$moduclass_lang)
!endif
!read lang/names.phtml.$moduclass_lang
!read adm/class/classname.phtml $wims_classname\
$wims_institutionname

!header1
!read adm/title.phtml 1\
$classname\
$module_title

!set wims_menu_items=!append line usermanage,1,module=adm/class/usermanage\
 to $wims_menu_items
!if $cmd!=reply or $step=0
$name_intro

!form reply
<div class="wimscenter wimsform"><input type="submit" name="reg" value="$wims_name_tosave"></div>

$name_expert
!set wims_ref_class=wims_button_help
!href cmd=help $wims_name_help
<fieldset class="property_fields blockcenter">
 <legend>$name_menu</legend>
 <div class="field box">
 !set wims_ref_class=wims_formradio
 <p>
!formcheckbox job list filter prompt <b>$wims_name_filter:</b>
$name_expert3
</p>
 !read adm/vfilter/varfilter htmldiv
 </div>
 <div class="field box">
 !formcheckbox job list login prompt $name_loginlist
   <textarea name="loginlist" cols="20" rows="5">$loginlist</textarea>
</div>
</fieldset>

!formend
!goto end
!endif

!if $photourl_exists=0
 <p class="wimscenter">$name_nophoto</p>
 !goto end
!endif
!if $class_type=0 or $class_typename=course or ($class_typename=class and $class_type=1)
  !set tmp=adm/class/userscore&job=getuser
!else
  !set tmp=adm/class/usermanage&job=userprop
!endif

<ul class="inline wims_nopuce">
!for l_ = 1 to $cnt
  !set ll=$[ceil($l_/$lim)]
  !set u=!line $[$l_ - ($ll-1)*$lim] of $(list_user$ll)
  !if $(u[1])!=
    <li>
    !if $(u[4])!=
      !if yes=$(u[4])
        !href module=$tmp&getuser=$(u[1]) <img border="0" width="132px" src="$wims_ref_name?session=$wims_session&cmd=getfile&special_parm=photoboard/$(u[1])" alt="$(u[2]) $(u[3])">
      !else
        !href module=$tmp&getuser=$(u[1]) <img border="0" width="120px" src="$(u[4])" alt="$(u[2]) $(u[3])">
      !endif
      <br>$(u[2]) $(u[3])
    !else
      !href module=$tmp&getuser=$(u[1]) $(u[2]) $(u[3])
    !endif
   </li>
  !endif
  !reset u
!next
</ul>
!reset tmp
!if $cmd=reply
  !set wims_menu_items=!append line back2,1,cmd=resume\
    to $wims_menu_items
!endif
:end
!tail
