!if \ isin $parm1
  !for p in 1
    !set parm$p=!slashsubst $(parm$p)
  !next p
!endif

!set add=$parm1
!set parms=!slashsubst $(parms)
!if ? isin $add
  !set add=!translate internal ? to , in $add
  !set add=!item 2 of $add
!endif
!set eq==
!!for exercices and tools in a class, syntax of the form numero_sheet/numero_exercise
!if $eq notin $add and $wims_class>0 and / isin $add \
    and $prim iswordof exercise tool
  !set add=!translate internal / to $ $ in $add
  !distribute words $add into sh_,ex_
  !distribute lines $(m_infoexo$ex_) into m_,p_,a_,b_,t_,d_
  !set prompt=!item 2 to -1 of $parms
  !default prompt=$t_
  !href session=$wims_session&cmd=new&module=$m_&worksheet=$sh_&$p_ $prompt
  !exit
!endif
!set add=!translate internal & to $ $ in $add
!set n=!wordcnt $add
!reset nadd,lmod,lses,lcmd
!for i=1 to $n
  !set l=!word $i of $add
  !set ll=!translate = to , in $l
  !distribute items $ll into l1,l2
  !if $l1=cmd and $l2 iswordof intro help close
    !set lcmd=$l2
  !endif
  !if $l1=module
    !set lmod=$l2
  !endif
  !if $l1 notwordof module cmd session
    !set nadd=$nadd $l
  !endif
!next i
!default lmod=home
!default lcmd=new
!set nadd=!translate internal $ $ to & in $nadd
!set prompt=!item 2 to -1 of $parms
!default prompt=!module title $lmod

!default prompt=Unknown activity

!if $prim=tool
  !href target=wims_tool module=$lmod&cmd=$lcmd$nadd $prompt
!else
  !href module=$lmod&cmd=$lcmd$nadd $prompt
!endif
