
<h1 class="wims_docu_title">$tit</h1>

!if $fcnt<1
  <p>
   $n_nocontent
  !href cmd=reply&job=edit&block=main $n_begin
  .
  </p>
  !exit
!endif

$table_header
<caption>$n_blocklist</caption>
$table_hdtr
<th>$wims_name_name</th><th>$wims_name_title</th><th>$wims_name_navigation</th><th>$wims_name_action</th></tr>
!for i=1 to $fcnt
  !set s_=!line $i of $slist
  !set t_=!line $i of $tlist
  !set t_=!trim $t_
  !default t_=$n_notitle
  $table_tr
  <td class="tt">$s_</td>
  <td>$t_</td>
  <td style="text-align:left">
  !if $s_!=main
    !reset prev next upbl
    !set navig=!defof prev,next,upbl in $docdir/$doc/src/$s_.hd
    !if $(navig[1])$(navig[2])$(navig[3]) =$empty
      !set navig=!defof prev,next,upbl in $docdir/$doc/$s_.def
    !endif
    <ul style="list-style-type:none">
    <li>$name_prev: <span class="tt">$(navig[1])</span></li>
    <li>$name_next: <span class="tt">$(navig[2])</span></li>
    <li>$name_up: <span class="tt">$(navig[3])</span></li>
    </ul>
  !endif
  </td><td>
  !set wims_ref_class=wims_button
  !href cmd=reply&job=read&block=$s_ $n_read
&nbsp;
  !if $editable=yes
    !set wims_ref_class=wims_button
    !href cmd=reply&job=edit&block=$s_ $wims_name_Edit
&nbsp;
    !if $s_!=main
      !set wims_ref_class=wims_button
      !href cmd=reply&job=list&job2=erase&block=$s_ $wims_name_erase
    !endif
  !endif
  </td>
  </tr>
!next i
$table_end
<div class="wimscenter tt">
  !if $doctype!=class
    $n_freespace1 $quota_total Meg.
    $n_freespace2 $quota_free Meg.
  !else
    !read adm/class/quotafree.proc html
  !endif
</div>
!set wims_menu_items=!append line properties,1,cmd=reply&job=prop\
doch_upload,1,cmd=reply&job=file\
doch_main,1, cmd=reply&job=read&block=main\
to $wims_menu_items
