<div class="wims_msg warning">
!if dontknow iswordof $error
  En fait, la dernière étape
  !if $step_reason=OK
    est correcte. $step_remark
  !else
    n'est pas correcte. $step_remark
    <div>
    !read reasons/$step_reason.det
    </div>
    Une version correcte de la dernière étape sera
    <div class="wimscenter">
    !line $step of $good
    </div>
  !endif
  <p>
  Dommage que vous n'ayez pas pu voir tout ça.
  </p>
  !goto gnext
!endif

<b>$wims_name_Error.</b>

!if step_error iswordof $error
  !if $step_reason=OK
    Mais si, cette étape est parfaitement correcte&nbsp;!
    $step_remark
  !else
    !if $ask_reason>0 and $step_reason!=$ans
      Non, la dernière étape est bien erronée, mais pas à cause de ce que vous pensez.
    !else
      Mais non, il y a bien une erreur dans la dernière étape.
    !endif
    $step_remark
    <div>
    !read reasons/$step_reason.det
    </div>
    Une version correcte de la dernière étape sera
    <div class="wimscenter">
    !line $step of $good
    </div>
  !endif
  :gnext
  </div>
  <p>
  !if $step<$stepcnt
    !set wims_ref_class=wims_button
    !href cmd=reply&ans=next Passer à l'étape suivante.
  !else
    Cet exercice est terminé. Votre note&nbsp;: $module_score/10.
  !endif
  </p>
  !exit
!endif

!if bad_step iswordof $error
  !if $badstep=0
    Vous pensez que toutes les étapes sont correctes.
  !else
    Vous pensez que la première mauvaise étape est le numéro $badstep.
  !endif
  !if $bad_steps=$empty
    Vous avez tort&nbsp;: toutes les étapes sont correctes.
    <p>
    !line $badstep of $remarks
    </p>
  !else
    Non, la <em>première</em> mauvaise étape est le numéro $sss.
    !if $badstep>0
      !if $badstep isitemof $bad_steps
        L'étape $badstep est bien erronée, mais elle n'est pas la première mauvaise étape.
      !else
        Par contre, l'étape $badstep est tout à fait juste.
      !endif
    !else
      $bad_reason
      <div>
      !set rrr=!item 1 of $bad_reasons
      !read reasons/$rrr.det
      </div>
    !endif
  !endif
  </div>
  <p>Votre note&nbsp;: $module_score/10.</p>
  !exit
!endif

!msg $error
