# Copyright(c) 1986 Association of Universities for Research in Astronomy Inc.

# AHIV -- Compute the high value (maximum) of a vector.

PIXEL procedure ahiv$t (a, npix)

PIXEL	a[ARB]
int	npix
PIXEL	high, pixval
$if (datatype == x)
real	abs_high
$endif
int	i

begin
	high = a[1]
	$if (datatype == x)
	abs_high = abs (high)
	$endif

	do i = 1, npix {
	    pixval = a[i]
	    $if (datatype == x)
	    if (abs (pixval) > abs_high) {
		high = pixval
		abs_high = abs (high)
	    }
	    $else
	    if (pixval > high)
		high = pixval
	    $endif
	}

	return (high)
end
